git.pond.sub.org Git - empserver/blob - configure.ac

   1 #
   2 #   Empire - A multi-player, client/server Internet based war game.
   3 #   Copyright (C) 1986-2021, Dave Pare, Jeff Bailey, Thomas Ruschak,
   4 #                 Ken Stevens, Steve McClure, Markus Armbruster
   5 #
   6 #   Empire is free software: you can redistribute it and/or modify
   7 #   it under the terms of the GNU General Public License as published by
   8 #   the Free Software Foundation, either version 3 of the License, or
   9 #   (at your option) any later version.
  10 #
  11 #   This program is distributed in the hope that it will be useful,
  12 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 #   GNU General Public License for more details.
  15 #
  16 #   You should have received a copy of the GNU General Public License
  17 #   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 #
  19 #   ---
  20 #
  21 #   See files README, COPYING and CREDITS in the root of the source
  22 #   tree for related information and legal notices.  It is expected
  23 #   that future projects/authors will amend these files as needed.
  24 #
  25 #   ---
  26 #
  27 #   configure.ac: Autoconf input file
  28 #
  29 #   Known contributors to this file:
  30 #      Markus Armbruster, 2005-2020
  31 #
  32 # Process this file with autoconf to produce a configure script.
  33
  34 # Autoconf makes checking for and programming around assorted ancient
  35 # crap relatively painless.  But why bother?  Just rely on POSIX, and
  36 # when something breaks on some oddball machine, see whether it's
  37 # worth fixing.
  38
  39 AC_PREREQ(2.69)
  40 AC_INIT([Wolfpack Empire],
  41         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  42         [wolfpack@wolfpackempire.com], [empire],
  43         [http://www.wolfpackempire.com/])
  44 AC_CONFIG_SRCDIR([include/combat.h])
  45 AC_CONFIG_AUX_DIR([build-aux])
  46 AC_CONFIG_MACRO_DIR([m4])
  47 AC_CONFIG_HEADERS([config.h])
  48
  49 ### Checks for programs
  50 AC_PROG_AWK
  51 AC_PROG_INSTALL
  52 AC_PROG_RANLIB
  53
  54 AC_PROG_CC_STDC
  55 AM_PROG_CC_C_O
  56 # Private automake macro, tsk, tsk, tsk...
  57 _AM_DEPENDENCIES(CC)
  58 AC_DEFINE([_XOPEN_SOURCE], [600],
  59           [Request POSIX-1.2001 with XSI Extension])
  60 # Note: this is after AC_PROG_CC_STDC, because Solaris cc fails with
  61 # _XOPEN_SOURCE unless switched to C99, which breaks AC_PROG_CC_STDC.
  62
  63 AC_ARG_VAR(NROFF, [nroff command])
  64 AC_CHECK_PROG(NROFF, groff, [GROFF_NO_SGR= groff -Tascii -U], nroff)
  65
  66 # not really a check for a program, but close enough
  67 if test -d $srcdir/.git
  68 then revctrl=git
  69 else revctrl=
  70 fi
  71 if test "$revctrl" && test -r $srcdir/.tarball-version
  72 then AC_MSG_ERROR([$srcdir/.tarball-version must not exist])
  73 fi
  74 AC_SUBST(revctrl,$revctrl)
  75
  76 # Not a program, but need to check this early
  77 MY_WINDOWS_API
  78
  79
  80 ### Checks for libraries
  81 AX_PTHREAD
  82 LIBS_util="$LIBS"
  83 LIBS="$LIBS_SOCKETS $LIBS"
  84 AX_LIB_SOCKET_NSL
  85 LIBS_server="$LIBS"
  86 MY_WITH_READLINE
  87 MY_WITH_TERMINFO
  88 LIBS_client="$LIBS"
  89
  90
  91 ### Checks for header files
  92
  93
  94 ### Checks for typedefs, structures, and compiler characteristics
  95
  96 if test "$GCC"
  97 then
  98
  99 # Enable useful warnings
 100 # Some of them are commented out because the code needs cleanup first
 101 # Clang needs to be tested with -Werror=unknown-warning-option
 102 AX_CHECK_COMPILE_FLAG([-Werror=unknown-warning-option],
 103 [cflags_test="-Werror=unknown-warning-option"],
 104 [cflags_test=""])
 105 MY_APPEND_COMPILE_FLAGS([-Wall -Wextra dnl
 106 dnl -Wcast-align dnl
 107 dnl -Wconversion dnl
 108 -Wdeclaration-after-statement dnl
 109 dnl -Wformat-nonliteral dnl
 110 -Wformat-security dnl
 111 -Winit-self dnl
 112 -Wlogical-op dnl
 113 -Wmissing-prototypes dnl
 114 -Wnested-externs dnl
 115 -Wold-style-definition dnl
 116 -Wpacked dnl
 117 -Wpointer-arith dnl
 118 -Wredundant-decls dnl
 119 dnl -Wshadow dnl
 120 -Wstrict-prototypes dnl
 121 dnl too prone to false positives: -Wsuggest-attribute=format dnl
 122 dnl -Wswitch-default dnl
 123 -Wundef dnl
 124 -Wno-unused-parameter dnl
 125 ], [], [$cflags_test])
 126
 127 # No multiple definitions of uninitialized global variables
 128 MY_APPEND_COMPILE_FLAGS([-fno-common])
 129
 130 # Reign in overzealous optimizers
 131 #
 132 # Contemporary compilers can squeeze out some extra performance by
 133 # assuming the program never executes code that has undefined behavior
 134 # according to the C standard.  Unfortunately, this can break
 135 # programs.  Pointing out that these programs are non-conforming is as
 136 # correct as it is unhelpful, at least as long as the compiler is
 137 # unable to diagnose the non-conformingness.
 138 #
 139 # Since keeping our programs working is a lot more important to us
 140 # than running them as fast as possible, forbid some assumptions that
 141 # are known to break real-world programs:
 142 #
 143 # * Aliasing: perfectly clean programs don't engage in type-punning,
 144 #   and perfectly conforming programs do it only in full accordance
 145 #   with the standard's (subtle!) aliasing rules.  Neither kind of
 146 #   perfection is realistic for us, therefore -fno-strict-aliasing.
 147 #
 148 # * Signed integer overflow: perfectly clean programs won't ever do
 149 #   signed integer arithmetic that overflows.  This is an imperfect
 150 #   program, therefore -fno-strict-overflow.
 151 #
 152 MY_APPEND_COMPILE_FLAGS([dnl
 153 -fno-strict-aliasing dnl
 154 -fno-strict-overflow])
 155
 156 # Emit extra code to check for buffer overflows
 157 # Could fall back to -fstack-protector when -fstack-protector-strong
 158 # isnt't supported, for users of older compilers.  Doesn't seem worth
 159 # the trouble, though.
 160 # Some ports of the GNU toolchain reportedly support it in the
 161 # compiler, but not libc.  Use a test program that makes the compiler
 162 # emit the extra stack checking code, and test it compiles and links.
 163 AX_APPEND_LINK_FLAGS([-fstack-protector-strong], [], [],
 164     [AC_LANG_SOURCE([[
 165 int
 166 main(int argc, char *argv[])
 167 {
 168     char arr[64], *dst = arr, *src = argv[0];
 169     while ((*dst++ = *src++)) ;
 170 }
 171     ]])])
 172
 173 fi # $GCC
 174
 175
 176 ### Checks for library functions
 177
 178 AC_CHECK_FUNCS(getaddrinfo)
 179 MY_WORKING_IN6_IS_ADDR_V4MAPPED
 180 MY_FUNC_MAKECONTEXT
 181
 182
 183 ### Site configuration
 184
 185 # Can't be bothered to make MAXNOC configurable right now.
 186 AC_DEFINE([MAXNOC], [99],
 187           [The maximum number of countries])
 188
 189 AC_ARG_VAR([EMPIREHOST], [Default host (client only) [127.0.0.1]])
 190 test "$EMPIREHOST" || EMPIREHOST=127.0.0.1
 191
 192 AC_ARG_VAR([EMPIREPORT], [Default port (client and server) [6665]])
 193 test "$EMPIREPORT" || EMPIREPORT=6665
 194
 195 AC_ARG_WITH([pthread],
 196             AS_HELP_STRING([--with-pthread],
 197                            [use POSIX threads]))
 198
 199 # Select thread package
 200 empthread=
 201 if test "$with_pthread" != no; then
 202     if test "$ax_pthread_ok" = yes; then
 203         empthread=POSIX
 204     fi
 205 fi
 206 if test -z "$with_pthread" || test "$with_pthread" = no; then
 207     if test "$ac_cv_func_makecontext" = yes; then
 208         empthread=LWP
 209     fi
 210     if test $Windows_API = yes; then
 211         empthread=Windows
 212     fi
 213 fi
 214 if test -z "$empthread"; then
 215     AC_MSG_ERROR([No usable thread package found])
 216 fi
 217 AC_SUBST(empthread)
 218 case $empthread in
 219 LWP)    AC_DEFINE([EMPTH_LWP], 1, [Define to use LWP threads]) ;;
 220 POSIX)  AC_DEFINE([EMPTH_POSIX], 1, [Define to use POSIX threads]) ;;
 221 Windows) AC_DEFINE([EMPTH_W32], 1, [Define to use Windows threads]) ;;
 222 esac
 223
 224
 225 ### Output
 226
 227 LIBS="$LIBS_util"
 228 AC_SUBST(LIBS_client)
 229 AC_SUBST(LIBS_server)
 230
 231 AC_CONFIG_FILES([GNUmakefile])
 232 AC_CONFIG_COMMANDS([stamp-h],
 233         [case $revctrl in
 234         git)
 235             mkdir -p `cd $srcdir && git ls-files \
 236                 | sed -n 's,/@<:@^/@:>@*$,,gp' | uniq`
 237             ;;
 238         *)
 239             mkdir -p `sed s/.*=// <$srcdir/sources.mk | tr ' ' '\012' \
 240                 | sed -n '/\//s,/@<:@^/@:>@*$,,gp'| uniq`
 241         esac
 242         mkdir -p info.html info.nr lib
 243         touch stamp-h],
 244         [revctrl=$revctrl])
 245 AC_OUTPUT
 246
 247 AC_MSG_NOTICE([])
 248 AC_MSG_NOTICE([-= Configuration summary =-])
 249 AC_MSG_NOTICE([Thread package: $empthread])
 250 AC_MSG_NOTICE([      readline: $with_readline])
 251 AC_MSG_NOTICE([      terminfo: $with_terminfo])
 252 AC_MSG_NOTICE([    EMPIREHOST: $EMPIREHOST])
 253 AC_MSG_NOTICE([    EMPIREPORT: $EMPIREPORT])