git.pond.sub.org Git - empserver/blob - configure.ac

   1 #
   2 #   Empire - A multi-player, client/server Internet based war game.
   3 #   Copyright (C) 1986-2015, Dave Pare, Jeff Bailey, Thomas Ruschak,
   4 #                 Ken Stevens, Steve McClure, Markus Armbruster
   5 #
   6 #   Empire is free software: you can redistribute it and/or modify
   7 #   it under the terms of the GNU General Public License as published by
   8 #   the Free Software Foundation, either version 3 of the License, or
   9 #   (at your option) any later version.
  10 #
  11 #   This program is distributed in the hope that it will be useful,
  12 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 #   GNU General Public License for more details.
  15 #
  16 #   You should have received a copy of the GNU General Public License
  17 #   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 #
  19 #   ---
  20 #
  21 #   See files README, COPYING and CREDITS in the root of the source
  22 #   tree for related information and legal notices.  It is expected
  23 #   that future projects/authors will amend these files as needed.
  24 #
  25 #   ---
  26 #
  27 #   configure.ac: Autoconf input file
  28 #
  29 #   Known contributors to this file:
  30 #      Markus Armbruster, 2005-2015
  31 #
  32 # Process this file with autoconf to produce a configure script.
  33
  34 # Autoconf makes checking for and programming around assorted ancient
  35 # crap relatively painless.  But why bother?  Just rely on C89 and
  36 # POSIX, and when something breaks on some oddball machine, see
  37 # whether it's worth fixing.
  38
  39 AC_PREREQ(2.64)
  40 AC_INIT([Wolfpack Empire], [4.3.34], [wolfpack@wolfpackempire.com], [empire],
  41         [http://www.wolfpackempire.com/])
  42 AC_CONFIG_SRCDIR([include/combat.h])
  43 AC_CONFIG_AUX_DIR([build-aux])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CONFIG_HEADERS([config.h])
  46
  47
  48 ### Checks for programs
  49 AC_PROG_AWK
  50 AC_PROG_INSTALL
  51 AC_PROG_RANLIB
  52 AC_PROG_CC
  53 AM_PROG_CC_C_O
  54 # Private automake macro, tsk, tsk, tsk...
  55 _AM_DEPENDENCIES(CC)
  56
  57 AC_ARG_VAR(NROFF, [nroff command])
  58 AC_CHECK_PROG(NROFF, groff, [GROFF_NO_SGR= groff -Tascii -U], nroff)
  59
  60 # not really a check for a program, but close enough
  61 if test -d $srcdir/.git; then revctrl=git
  62 else revctrl=
  63 fi
  64 AC_SUBST(revctrl,$revctrl)
  65
  66 # Not a program, but need to check this early
  67 MY_WINDOWS_API
  68
  69
  70 ### Checks for libraries
  71 AX_PTHREAD
  72 LIBS_util="$LIBS"
  73 LIBS="$LIBS_SOCKETS $LIBS"
  74 AX_LIB_SOCKET_NSL
  75 LIBS_server="$LIBS"
  76
  77
  78 ### Checks for header files
  79
  80
  81 ### Checks for typedefs, structures, and compiler characteristics
  82
  83 # Enable useful warnings
  84 # clang needs to be tested with -Werror=unknown-warning-option
  85 AX_CHECK_COMPILE_FLAG([-Werror=unknown-warning-option],
  86 [cflags_test="-Werror=unknown-warning-option"],
  87 [cflags_test=""])
  88 MY_APPEND_COMPILE_FLAGS([-Wall -Wextra dnl
  89 -Wmissing-prototypes dnl
  90 -Wnested-externs dnl
  91 -Wpointer-arith dnl
  92 -Wredundant-decls dnl
  93 -Wstrict-prototypes dnl
  94 -Wno-unused-parameter dnl
  95 ], [], [$cflags_test])
  96
  97 # Our carg() conflicts with libm's TODO clean that up
  98 MY_APPEND_COMPILE_FLAGS([-fno-builtin-carg])
  99
 100 # No multiple definitions of uninitialized global variables
 101 MY_APPEND_COMPILE_FLAGS([-fno-common])
 102
 103
 104 ### Checks for library functions
 105
 106 AC_CHECK_FUNCS(getaddrinfo getpass)
 107 MY_FUNC_MAKECONTEXT
 108
 109
 110 ### Site configuration
 111
 112 # Can't be bothered to make MAXNOC configurable right now.
 113 AC_DEFINE([MAXNOC], [99],
 114           [The maximum number of countries])
 115
 116 AC_ARG_VAR([EMPIREHOST], [Default host (client only) [127.0.0.1]])
 117 test "$EMPIREHOST" || EMPIREHOST=127.0.0.1
 118
 119 AC_ARG_VAR([EMPIREPORT], [Default port (client and server) [6665]])
 120 test "$EMPIREPORT" || EMPIREPORT=6665
 121
 122 AC_ARG_WITH([pthread],
 123             AS_HELP_STRING([--with-pthread],
 124                            [use POSIX threads]))
 125
 126 # Select thread package
 127 empthread=
 128 if test "$with_pthread" != no; then
 129     if test "$ax_pthread_ok" = yes; then
 130         empthread=POSIX
 131     fi
 132 fi
 133 if test -z "$with_pthread" || test "$with_pthread" = no; then
 134     if test "$ac_cv_func_makecontext" = yes; then
 135         empthread=LWP
 136     fi
 137     if test $Windows_API = yes; then
 138         empthread=Windows
 139     fi
 140 fi
 141 if test -z "$empthread"; then
 142     AC_MSG_ERROR([No usable thread package found])
 143 fi
 144 AC_SUBST(empthread)
 145 case $empthread in
 146 LWP)    AC_DEFINE([EMPTH_LWP], 1, [Define to use LWP threads]) ;;
 147 POSIX)  AC_DEFINE([EMPTH_POSIX], 1, [Define to use POSIX threads]) ;;
 148 Windows) AC_DEFINE([EMPTH_W32], 1, [Define to use Windows threads]) ;;
 149 esac
 150
 151 MY_WITH_TERMINFO
 152 LIBS_client="$LIBS"
 153
 154
 155 ### Output
 156
 157 LIBS="$LIBS_util"
 158 AC_SUBST(LIBS_client)
 159 AC_SUBST(LIBS_server)
 160
 161 AC_CONFIG_FILES([GNUmakefile])
 162 AC_CONFIG_COMMANDS([stamp-h],
 163         [case $revctrl in
 164         git)
 165             mkdir -p `cd $srcdir && git ls-files \
 166                 | sed -n 's,/@<:@^/@:>@*$,,gp' | uniq`
 167             ;;
 168         *)
 169             mkdir -p `sed s/.*=// <$srcdir/sources.mk | tr ' ' '\012' \
 170                 | sed -n '/\//s,/@<:@^/@:>@*$,,gp'| uniq`
 171         esac
 172         mkdir -p info.html info.nr lib
 173         touch stamp-h],
 174         [revctrl=$revctrl])
 175 AC_OUTPUT
 176
 177 AC_MSG_NOTICE([])
 178 AC_MSG_NOTICE([-= Configuration summary =-])
 179 AC_MSG_NOTICE([Thread package: $empthread])
 180 AC_MSG_NOTICE([      terminfo: $with_terminfo])
 181 AC_MSG_NOTICE([    EMPIREHOST: $EMPIREHOST])
 182 AC_MSG_NOTICE([    EMPIREPORT: $EMPIREPORT])