git.pond.sub.org Git - empserver/blob - configure.ac

   1 #
   2 #   Empire - A multi-player, client/server Internet based war game.
   3 #   Copyright (C) 1986-2006, Dave Pare, Jeff Bailey, Thomas Ruschak,
   4 #                            Ken Stevens, Steve McClure
   5 #
   6 #   This program is free software; you can redistribute it and/or modify
   7 #   it under the terms of the GNU General Public License as published by
   8 #   the Free Software Foundation; either version 2 of the License, or
   9 #   (at your option) any later version.
  10 #
  11 #   This program is distributed in the hope that it will be useful,
  12 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 #   GNU General Public License for more details.
  15 #
  16 #   You should have received a copy of the GNU General Public License
  17 #   along with this program; if not, write to the Free Software
  18 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  19 #
  20 #   ---
  21 #
  22 #   See files README, COPYING and CREDITS in the root of the source
  23 #   tree for related information and legal notices.  It is expected
  24 #   that future projects/authors will amend these files as needed.
  25 #
  26 #   ---
  27 #
  28 #   configure.ac: Autoconf input file
  29 #
  30 #   Known contributors to this file:
  31 #      Markus Armbruster, 2005
  32 #
  33 # Process this file with autoconf to produce a configure script.
  34
  35 # Autoconf makes checking for and programming around assorted ancient
  36 # crap relatively painless.  But why bother?  Just rely on C89 and
  37 # POSIX, and when something breaks on some oddball machine, see
  38 # whether it's worth fixing.
  39
  40 AC_PREREQ(2.59)
  41 AC_INIT([Wolfpack Empire], [4.3.2], [wolfpack@wolfpackempire.com], [empire])
  42 AC_CONFIG_SRCDIR([include/combat.h])
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_CONFIG_HEADERS([config.h])
  45
  46
  47 ### Checks for programs
  48 AC_PROG_AWK
  49 AC_PROG_INSTALL
  50 AC_PROG_RANLIB
  51 AC_PROG_CC
  52 AC_SUBST(GCC)
  53 AM_PROG_CC_C_O
  54 # Private automake macro, tsk, tsk, tsk...
  55 _AM_DEPENDENCIES(CC)
  56
  57 # not really a check for a program, but close enough
  58 if test -d $srcdir/CVS; then cvs_controlled=yes; else cvs_controlled=no; fi
  59 AC_SUBST(cvs_controlled,$cvs_controlled)
  60
  61
  62 ### Checks for libraries
  63 ACX_PTHREAD
  64 LIB_SOCKET_NSL
  65 # TODO merge this into LIB_SOCKET_NSL?
  66 case "$host_os" in
  67 *mingw32)
  68     LIBS="-lws2_32 $LIBS" ;;
  69 esac
  70
  71 # TODO turn this into a macro?
  72 save_LIBS=$LIBS
  73 AC_SEARCH_LIBS([setupterm], [termlib termcap curses])
  74 termlibs=`echo $LIBS | sed s/\`echo $save_LIBS | sed 's/././g'\`'$//'`
  75 AC_SUBST(termlibs)
  76 LIBS=$save_LIBS
  77
  78
  79 ### Checks for header files
  80
  81
  82 ### Checks for typedefs, structures, and compiler characteristics
  83
  84 AC_C_CHAR_UNSIGNED
  85
  86
  87 ### Checks for library functions
  88
  89 AC_CHECK_FUNCS(getaddrinfo)
  90 MY_FUNC_MAKECONTEXT
  91
  92
  93 ### Site configuration
  94
  95 # Can't be bothered to make MAXNOC configurable right now.
  96 AC_DEFINE([MAXNOC], [99],
  97           [The maximum number of countries])
  98
  99 AC_ARG_VAR([EMPIREHOST], [Default host (client only) [127.0.0.1]])
 100 test "$EMPIREHOST" || EMPIREHOST=127.0.0.1
 101
 102 AC_ARG_VAR([EMPIREPORT], [Default port (client and server) [6665]])
 103 test "$EMPIREPORT" || EMPIREPORT=6665
 104
 105 AC_ARG_WITH([pthread],
 106             AS_HELP_STRING([--with-pthread],
 107                            [use POSIX threads]))
 108
 109 # Select thread package
 110 empthread=
 111 if test "$with_pthread" != no; then
 112     if test "$acx_pthread_ok" = yes; then
 113         empthread=POSIX
 114     fi
 115 fi
 116 if test -z "$with_pthread" || test "$with_pthread" = no; then
 117     if test "$ac_cv_func_makecontext" = yes; then
 118         empthread=LWP
 119     fi
 120     case "$host_os" in
 121     *mingw32)
 122         empthread=Windows ;;
 123     esac
 124 fi
 125 if test -z "$empthread"; then
 126     AC_MSG_ERROR([No usable thread package found])
 127 fi
 128 AC_SUBST(empthread)
 129 AC_MSG_NOTICE([Using $empthread threads])
 130 case $empthread in
 131 LWP)    AC_DEFINE([EMPTH_LWP], 1, [Define to use LWP threads])
 132         AC_DEFINE([UCONTEXT], 1, [Define to make LWP use makecontext()]) ;;
 133 POSIX)  AC_DEFINE([EMPTH_POSIX], 1, [Define to use POSIX threads]) ;;
 134 Windows) AC_DEFINE([EMPTH_W32], 1, [Define to use Windows threads]) ;;
 135 esac
 136
 137
 138 ### Output
 139
 140 AC_CONFIG_FILES([GNUmakefile])
 141 AC_CONFIG_COMMANDS([stamp-h],
 142         [if test $cvs_controlled = yes; then
 143             mkdir -p `cd $srcdir && $AWK -f src/scripts/cvsfiles.awk \
 144                 | sed -n '/\//s,/@<:@^/@:>@*$,,gp'| uniq`
 145         else
 146             mkdir -p `sed s/.*=// <$srcdir/sources.mk | tr ' ' '\012' \
 147                 | sed -n '/\//s,/@<:@^/@:>@*$,,gp'| uniq`
 148         fi
 149         mkdir -p info.html info.nr lib
 150         touch stamp-h],
 151         [cvs_controlled=$cvs_controlled; AWK=$AWK])
 152 AC_OUTPUT