git.pond.sub.org Git - empserver/blob - configure.ac

   1 #
   2 #   Empire - A multi-player, client/server Internet based war game.
   3 #   Copyright (C) 1986-2006, Dave Pare, Jeff Bailey, Thomas Ruschak,
   4 #                            Ken Stevens, Steve McClure
   5 #
   6 #   This program is free software; you can redistribute it and/or modify
   7 #   it under the terms of the GNU General Public License as published by
   8 #   the Free Software Foundation; either version 2 of the License, or
   9 #   (at your option) any later version.
  10 #
  11 #   This program is distributed in the hope that it will be useful,
  12 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 #   GNU General Public License for more details.
  15 #
  16 #   You should have received a copy of the GNU General Public License
  17 #   along with this program; if not, write to the Free Software
  18 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  19 #
  20 #   ---
  21 #
  22 #   See files README, COPYING and CREDITS in the root of the source
  23 #   tree for related information and legal notices.  It is expected
  24 #   that future projects/authors will amend these files as needed.
  25 #
  26 #   ---
  27 #
  28 #   configure.ac: Autoconf input file
  29 #
  30 #   Known contributors to this file:
  31 #      Markus Armbruster, 2005
  32 #
  33 # Process this file with autoconf to produce a configure script.
  34
  35 # Autoconf makes checking for and programming around assorted ancient
  36 # crap relatively painless.  But why bother?  Just rely on C89 and
  37 # POSIX, and when something breaks on some oddball machine, see
  38 # whether it's worth fixing.
  39
  40 AC_PREREQ(2.59)
  41 AC_INIT([Wolfpack Empire], [4.3.4], [wolfpack@wolfpackempire.com], [empire])
  42 AC_CONFIG_SRCDIR([include/combat.h])
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_CONFIG_HEADERS([config.h])
  45
  46
  47 ### Checks for programs
  48 AC_PROG_AWK
  49 AC_PROG_INSTALL
  50 AC_PROG_RANLIB
  51 AC_PROG_CC
  52 AC_SUBST(GCC)
  53 AM_PROG_CC_C_O
  54 # Private automake macro, tsk, tsk, tsk...
  55 _AM_DEPENDENCIES(CC)
  56
  57 # not really a check for a program, but close enough
  58 if test -d $srcdir/CVS; then cvs_controlled=yes; else cvs_controlled=no; fi
  59 AC_SUBST(cvs_controlled,$cvs_controlled)
  60
  61
  62 ### Checks for libraries
  63 ACX_PTHREAD
  64 LIB_SOCKET_NSL
  65 # TODO merge this into LIB_SOCKET_NSL?
  66 case "$host_os" in
  67 *mingw32)
  68     LIBS="-lws2_32 $LIBS" ;;
  69 esac
  70
  71 # TODO turn this into a macro?
  72 save_LIBS=$LIBS
  73 AC_SEARCH_LIBS([setupterm], [termlib termcap curses ncurses])
  74 # FIXME if not found, complain and switch off highlighting
  75 termlibs=`echo $LIBS | sed s/\`echo $save_LIBS | sed 's/././g'\`'$//'`
  76 AC_SUBST(termlibs)
  77 LIBS=$save_LIBS
  78
  79
  80 ### Checks for header files
  81
  82
  83 ### Checks for typedefs, structures, and compiler characteristics
  84
  85 AC_C_CHAR_UNSIGNED
  86
  87
  88 ### Checks for library functions
  89
  90 AC_CHECK_FUNCS(getaddrinfo)
  91 MY_FUNC_MAKECONTEXT
  92
  93
  94 ### Site configuration
  95
  96 # Can't be bothered to make MAXNOC configurable right now.
  97 AC_DEFINE([MAXNOC], [99],
  98           [The maximum number of countries])
  99
 100 AC_ARG_VAR([EMPIREHOST], [Default host (client only) [127.0.0.1]])
 101 test "$EMPIREHOST" || EMPIREHOST=127.0.0.1
 102
 103 AC_ARG_VAR([EMPIREPORT], [Default port (client and server) [6665]])
 104 test "$EMPIREPORT" || EMPIREPORT=6665
 105
 106 AC_ARG_WITH([pthread],
 107             AS_HELP_STRING([--with-pthread],
 108                            [use POSIX threads]))
 109
 110 # Select thread package
 111 empthread=
 112 if test "$with_pthread" != no; then
 113     if test "$acx_pthread_ok" = yes; then
 114         empthread=POSIX
 115     fi
 116 fi
 117 if test -z "$with_pthread" || test "$with_pthread" = no; then
 118     if test "$ac_cv_func_makecontext" = yes; then
 119         empthread=LWP
 120     fi
 121     case "$host_os" in
 122     *mingw32)
 123         empthread=Windows ;;
 124     esac
 125 fi
 126 if test -z "$empthread"; then
 127     AC_MSG_ERROR([No usable thread package found])
 128 fi
 129 AC_SUBST(empthread)
 130 AC_MSG_NOTICE([Using $empthread threads])
 131 case $empthread in
 132 LWP)    AC_DEFINE([EMPTH_LWP], 1, [Define to use LWP threads])
 133         AC_DEFINE([UCONTEXT], 1, [Define to make LWP use makecontext()]) ;;
 134 POSIX)  AC_DEFINE([EMPTH_POSIX], 1, [Define to use POSIX threads]) ;;
 135 Windows) AC_DEFINE([EMPTH_W32], 1, [Define to use Windows threads]) ;;
 136 esac
 137
 138
 139 ### Output
 140
 141 AC_CONFIG_FILES([GNUmakefile])
 142 AC_CONFIG_COMMANDS([stamp-h],
 143         [if test $cvs_controlled = yes; then
 144             mkdir -p `cd $srcdir && $AWK -f src/scripts/cvsfiles.awk \
 145                 | sed -n '/\//s,/@<:@^/@:>@*$,,gp'| uniq`
 146         else
 147             mkdir -p `sed s/.*=// <$srcdir/sources.mk | tr ' ' '\012' \
 148                 | sed -n '/\//s,/@<:@^/@:>@*$,,gp'| uniq`
 149         fi
 150         mkdir -p info.html info.nr lib
 151         touch stamp-h],
 152         [cvs_controlled=$cvs_controlled; AWK=$AWK])
 153 AC_OUTPUT