git.pond.sub.org Git - empserver/blob - configure.ac

   1 #
   2 #   Empire - A multi-player, client/server Internet based war game.
   3 #   Copyright (C) 1986-2016, Dave Pare, Jeff Bailey, Thomas Ruschak,
   4 #                 Ken Stevens, Steve McClure, Markus Armbruster
   5 #
   6 #   Empire is free software: you can redistribute it and/or modify
   7 #   it under the terms of the GNU General Public License as published by
   8 #   the Free Software Foundation, either version 3 of the License, or
   9 #   (at your option) any later version.
  10 #
  11 #   This program is distributed in the hope that it will be useful,
  12 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 #   GNU General Public License for more details.
  15 #
  16 #   You should have received a copy of the GNU General Public License
  17 #   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 #
  19 #   ---
  20 #
  21 #   See files README, COPYING and CREDITS in the root of the source
  22 #   tree for related information and legal notices.  It is expected
  23 #   that future projects/authors will amend these files as needed.
  24 #
  25 #   ---
  26 #
  27 #   configure.ac: Autoconf input file
  28 #
  29 #   Known contributors to this file:
  30 #      Markus Armbruster, 2005-2015
  31 #
  32 # Process this file with autoconf to produce a configure script.
  33
  34 # Autoconf makes checking for and programming around assorted ancient
  35 # crap relatively painless.  But why bother?  Just rely on C89 and
  36 # POSIX, and when something breaks on some oddball machine, see
  37 # whether it's worth fixing.
  38
  39 AC_PREREQ(2.69)
  40 AC_INIT([Wolfpack Empire], [4.3.34], [wolfpack@wolfpackempire.com], [empire],
  41         [http://www.wolfpackempire.com/])
  42 AC_CONFIG_SRCDIR([include/combat.h])
  43 AC_CONFIG_AUX_DIR([build-aux])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CONFIG_HEADERS([config.h])
  46
  47
  48 ### Checks for programs
  49 AC_PROG_AWK
  50 AC_PROG_INSTALL
  51 AC_PROG_RANLIB
  52 AC_PROG_CC
  53 AM_PROG_CC_C_O
  54 # Private automake macro, tsk, tsk, tsk...
  55 _AM_DEPENDENCIES(CC)
  56
  57 AC_ARG_VAR(NROFF, [nroff command])
  58 AC_CHECK_PROG(NROFF, groff, [GROFF_NO_SGR= groff -Tascii -U], nroff)
  59
  60 # not really a check for a program, but close enough
  61 if test -d $srcdir/.git; then revctrl=git
  62 else revctrl=
  63 fi
  64 AC_SUBST(revctrl,$revctrl)
  65
  66 # Not a program, but need to check this early
  67 MY_WINDOWS_API
  68
  69
  70 ### Checks for libraries
  71 AX_PTHREAD
  72 LIBS_util="$LIBS"
  73 LIBS="$LIBS_SOCKETS $LIBS"
  74 AX_LIB_SOCKET_NSL
  75 LIBS_server="$LIBS"
  76
  77
  78 ### Checks for header files
  79
  80
  81 ### Checks for typedefs, structures, and compiler characteristics
  82
  83 # Enable useful warnings
  84 # Some of them are commented out because the code needs cleanup first
  85 # Clang needs to be tested with -Werror=unknown-warning-option
  86 AX_CHECK_COMPILE_FLAG([-Werror=unknown-warning-option],
  87 [cflags_test="-Werror=unknown-warning-option"],
  88 [cflags_test=""])
  89 MY_APPEND_COMPILE_FLAGS([-Wall -Wextra dnl
  90 dnl -Wcast-align dnl
  91 dnl -Wconversion dnl
  92 -Wdeclaration-after-statement dnl
  93 dnl -Wformat-nonliteral dnl
  94 -Wformat-security dnl
  95 -Winit-self dnl
  96 -Wlogical-op dnl
  97 -Wmissing-prototypes dnl
  98 -Wnested-externs dnl
  99 -Wold-style-definition dnl
 100 -Wpacked dnl
 101 -Wpointer-arith dnl
 102 -Wredundant-decls dnl
 103 dnl -Wshadow dnl
 104 -Wstrict-prototypes dnl
 105 dnl too prone to false positives: -Wsuggest-attribute=format dnl
 106 dnl -Wswitch-default dnl
 107 -Wundef dnl
 108 -Wno-unused-parameter dnl
 109 ], [], [$cflags_test])
 110
 111 # Our carg() conflicts with libm's TODO clean that up
 112 MY_APPEND_COMPILE_FLAGS([-fno-builtin-carg -Wno-incompatible-library-redeclaration])
 113
 114 # No multiple definitions of uninitialized global variables
 115 MY_APPEND_COMPILE_FLAGS([-fno-common])
 116
 117 # Reign in overzealous optimizers
 118 #
 119 # Contemporary compilers can squeeze out some extra performance by
 120 # assuming the program never executes code that has undefined behavior
 121 # according to the C standard.  Unfortunately, this can break
 122 # programs.  Pointing out that these programs are non-conforming is as
 123 # correct as it is unhelpful, at least as long as the compiler is
 124 # unable to diagnose the non-conformingness.
 125 #
 126 # Since keeping our programs working is a lot more important to us
 127 # than running them as fast as possible, forbid some assumptions that
 128 # are known to break real-world programs:
 129 #
 130 # * Aliasing: perfectly clean programs don't engage in type-punning,
 131 #   and perfectly conforming programs do it only in full accordance
 132 #   with the standard's (subtle!) aliasing rules.  Neither kind of
 133 #   perfection is realistic for us, therefore -fno-strict-aliasing.
 134 #
 135 # * Signed integer overflow: perfectly clean programs won't ever do
 136 #   signed integer arithmetic that overflows.  This is an imperfect
 137 #   program, therefore -fno-strict-overflow.
 138 #
 139 MY_APPEND_COMPILE_FLAGS([dnl
 140 -fno-strict-aliasing dnl
 141 -fno-strict-overflow])
 142
 143 # Emit extra code to check for buffer overflows
 144 # Could fall back to -fstack-protector when -fstack-protector-strong
 145 # isnt't supported, for users of older compilers.  Doesn't seem worth
 146 # the trouble, though.
 147 # Some ports of the GNU toolchain reportedly support it in the
 148 # compiler, but not libc.  Use a test program that makes the compiler
 149 # emit the extra stack checking code, and test it compiles and links.
 150 AX_APPEND_LINK_FLAGS([-fstack-protector-strong], [], [],
 151     [AC_LANG_SOURCE([[
 152 int
 153 main(int argc, char *argv[])
 154 {
 155     char arr[64], *dst = arr, *src = argv[0];
 156     while ((*dst++ = *src++)) ;
 157 }
 158     ]])])
 159
 160
 161 ### Checks for library functions
 162
 163 AC_CHECK_FUNCS(getaddrinfo getpass)
 164 MY_FUNC_MAKECONTEXT
 165
 166
 167 ### Site configuration
 168
 169 # Can't be bothered to make MAXNOC configurable right now.
 170 AC_DEFINE([MAXNOC], [99],
 171           [The maximum number of countries])
 172
 173 AC_ARG_VAR([EMPIREHOST], [Default host (client only) [127.0.0.1]])
 174 test "$EMPIREHOST" || EMPIREHOST=127.0.0.1
 175
 176 AC_ARG_VAR([EMPIREPORT], [Default port (client and server) [6665]])
 177 test "$EMPIREPORT" || EMPIREPORT=6665
 178
 179 AC_ARG_WITH([pthread],
 180             AS_HELP_STRING([--with-pthread],
 181                            [use POSIX threads]))
 182
 183 # Select thread package
 184 empthread=
 185 if test "$with_pthread" != no; then
 186     if test "$ax_pthread_ok" = yes; then
 187         empthread=POSIX
 188     fi
 189 fi
 190 if test -z "$with_pthread" || test "$with_pthread" = no; then
 191     if test "$ac_cv_func_makecontext" = yes; then
 192         empthread=LWP
 193     fi
 194     if test $Windows_API = yes; then
 195         empthread=Windows
 196     fi
 197 fi
 198 if test -z "$empthread"; then
 199     AC_MSG_ERROR([No usable thread package found])
 200 fi
 201 AC_SUBST(empthread)
 202 case $empthread in
 203 LWP)    AC_DEFINE([EMPTH_LWP], 1, [Define to use LWP threads]) ;;
 204 POSIX)  AC_DEFINE([EMPTH_POSIX], 1, [Define to use POSIX threads]) ;;
 205 Windows) AC_DEFINE([EMPTH_W32], 1, [Define to use Windows threads]) ;;
 206 esac
 207
 208 MY_WITH_TERMINFO
 209 LIBS_client="$LIBS"
 210
 211
 212 ### Output
 213
 214 LIBS="$LIBS_util"
 215 AC_SUBST(LIBS_client)
 216 AC_SUBST(LIBS_server)
 217
 218 AC_CONFIG_FILES([GNUmakefile])
 219 AC_CONFIG_COMMANDS([stamp-h],
 220         [case $revctrl in
 221         git)
 222             mkdir -p `cd $srcdir && git ls-files \
 223                 | sed -n 's,/@<:@^/@:>@*$,,gp' | uniq`
 224             ;;
 225         *)
 226             mkdir -p `sed s/.*=// <$srcdir/sources.mk | tr ' ' '\012' \
 227                 | sed -n '/\//s,/@<:@^/@:>@*$,,gp'| uniq`
 228         esac
 229         mkdir -p info.html info.nr lib
 230         touch stamp-h],
 231         [revctrl=$revctrl])
 232 AC_OUTPUT
 233
 234 AC_MSG_NOTICE([])
 235 AC_MSG_NOTICE([-= Configuration summary =-])
 236 AC_MSG_NOTICE([Thread package: $empthread])
 237 AC_MSG_NOTICE([      terminfo: $with_terminfo])
 238 AC_MSG_NOTICE([    EMPIREHOST: $EMPIREHOST])
 239 AC_MSG_NOTICE([    EMPIREPORT: $EMPIREPORT])