git.pond.sub.org Git - empserver/blob - info/mksubj.pl

   1 #!/usr/bin/perl
   2 #
   3 #   Empire - A multi-player, client/server Internet based war game.
   4 #   Copyright (C) 1986-2013, Dave Pare, Jeff Bailey, Thomas Ruschak,
   5 #                 Ken Stevens, Steve McClure, Markus Armbruster
   6 #
   7 #   Empire is free software: you can redistribute it and/or modify
   8 #   it under the terms of the GNU General Public License as published by
   9 #   the Free Software Foundation, either version 3 of the License, or
  10 #   (at your option) any later version.
  11 #
  12 #   This program is distributed in the hope that it will be useful,
  13 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #   GNU General Public License for more details.
  16 #
  17 #   You should have received a copy of the GNU General Public License
  18 #   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20 #   ---
  21 #
  22 #   See files README, COPYING and CREDITS in the root of the source
  23 #   tree for related information and legal notices.  It is expected
  24 #   that future projects/authors will amend these files as needed.
  25 #
  26 #   ---
  27 #
  28 #   mksubj.pl: Update the subject index pages
  29 #
  30 #   Known contributors to this file:
  31 #      Ken Stevens (when it was still info.pl)
  32 #      Markus Armbruster, 2006-2013
  33 #
  34 # Usage: mksubj.pl SUBJECT... INFO-FILE...
  35 #
  36 # Read the INFO-FILE..., update info/SUBJECT.t for each SUBJECT.
  37
  38 use strict;
  39 use warnings;
  40
  41 # The chapters, in order
  42 my @Chapters = qw/Introduction Concept Command Server/;
  43
  44 my @Levels = qw/Basic Expert Obsolete/;
  45
  46 # $Subjects{SUBJECT} is a reference to an an anonymous array
  47 # containing SUBJECT's topics
  48 my %Subjects;
  49
  50 # $filename{TOPIC} is TOPIC's file name
  51 my %filename;
  52 # $lines{TOPIC} is the number of lines in $filename{TOPIC}
  53 my %lines;
  54 # $chapter{TOPIC} is TOPIC's chapter (first arg to .TH)
  55 my %chapter;
  56 # $desc{TOPIC} is a one line description of TOPIC (second arg to .NA)
  57 my %desc;
  58 # $level{TOPIC} is TOPIC's difficulty level (arg to .LV)
  59 my %level;
  60
  61 # current info file
  62 my $filename;
  63
  64 while ($#ARGV >= 0 && $ARGV[0] !~ /\.t$/) {
  65     $Subjects{shift @ARGV} = [];
  66 }
  67
  68 for (@ARGV) {
  69     $filename{fn2topic($_)} = $_;
  70 }
  71
  72 for (@ARGV) {
  73     parse_file($_);
  74 }
  75
  76 for (keys %Subjects) {
  77     update_subj($_);
  78 }
  79
  80 sub fn2topic {
  81     my ($fn) = @_;
  82     $fn =~ s,.*/([^/]*)\.t$,$1,;
  83     return $fn;
  84 }
  85
  86 # Parse an info file
  87 # Set $filename, $lines{TOPIC}, $chapter{TOPIC}, $desc{TOPIC},
  88 # $level{TOPIC}.
  89 # Update %Subjects.
  90 sub parse_file {
  91     ($filename) = @_;
  92     my $topic = fn2topic($filename);
  93
  94     open(F, "<$filename")
  95         or die "Can't open $filename: $!";
  96
  97     $_ = <F>;
  98     if (/^\.TH (\S+) (\S.+\S)$/) {
  99         if (!grep(/^$1$/, @Chapters)) {
 100             error("First argument to .TH was '$1', which is not a known chapter");
 101         }
 102         $chapter{$topic} = $1;
 103         if ($1 eq "Command" && $2 ne "\U$topic") {
 104             error("Second argument to .TH was '$2' but it should be '\U$topic'");
 105         }
 106     } else {
 107         error("The first line in the file must be a .TH request");
 108     }
 109
 110     $_ = <F>;
 111     if (/^\.NA (\S+) "(\S.+\S)"$/) {
 112         if ($topic ne $1) {
 113             error("First argument to .NA was '$1' but it should be '$topic'");
 114         }
 115         $desc{$topic} = $2;
 116     } else {
 117         error("The second line in the file must be a .NA request");
 118     }
 119
 120     $_ = <F>;
 121     if (/^\.LV (\S+)$/) {
 122         if (!grep(/^$1$/, @Levels)) {
 123             error("The argument to .LV was '$1', which is not a known level");
 124         }
 125         $level{$topic} = $1;
 126     } else {
 127         error("The third line in the file must be a .LV request");
 128     }
 129
 130     while (<F>) {
 131         last if /^\.SA/;
 132     }
 133
 134     if ($_) {
 135         if (/^\.SA "([^\"]*)"/) {
 136             parse_see_also($topic, $1);
 137         } else {
 138             error("Incorrect .SA Syntax.  Syntax should be '.SA \"item1, item2\"'");
 139         }
 140     } else {
 141         error(".SA request is missing");
 142     }
 143
 144     if (<F>) {
 145         error(".SA request must be the last line");
 146     }
 147
 148     $lines{$topic} = $.;
 149     close F;
 150 }
 151
 152 sub parse_see_also {
 153     my ($topic, $sa) = @_;
 154     my $wanted = $chapter{$topic};
 155     my $found;                 # found a subject?
 156
 157     $wanted = undef if $wanted eq 'Concept' or $wanted eq 'Command';
 158
 159     for (split(/, /, $sa)) {
 160         next if exists $filename{$_};
 161         error("Unknown topic $_ in .SA") unless exists $Subjects{$_};
 162         push @{$Subjects{$_}}, $topic;
 163         $found = 1;
 164         if ($wanted && $_ eq $wanted) {
 165             $wanted = undef;
 166         }
 167     }
 168
 169     error("No subject listed in .SA") unless $found;
 170     error("Chapter $wanted not listed in .SA") if $wanted;
 171 }
 172
 173 # Update a Subject.t file
 174 sub update_subj {
 175     my ($subj) = @_;
 176     my $fname = "info/$subj.t";
 177     my @topics = @{$Subjects{$subj}};
 178     my $out = "";
 179     my ($any_topic, $any_basic, $any_obsolete, $any_long);
 180
 181     my $largest = "";
 182     for my $topic (@topics) {
 183         $largest = $topic if length $topic > length $largest;
 184     }
 185
 186     $out .= '.\" DO NOT EDIT THIS FILE.  It was automatically generated by mksubj.pl'."\n";
 187     $out .= ".TH Subject \U$subj\n";
 188     $largest =~ s/-/M/g;
 189     $out .= ".in \\w'$largest" . "XX\\0\\0\\0\\0'u\n";
 190
 191     for my $chap (@Chapters) {
 192         my $empty = 1;
 193         for my $topic (@topics) {
 194             $any_topic = 1;
 195             next if $chapter{$topic} ne $chap;
 196             $out .= ".s1\n" if $empty;
 197             $empty = 0;
 198             my $flags = "";
 199             if ($level{$topic} eq 'Basic') {
 200                 $flags .= "*";
 201                 $any_basic = 1;
 202             }
 203             if ($level{$topic} eq 'Obsolete') {
 204                 $flags .= "+";
 205                 $any_obsolete = 1;
 206             }
 207             if ($lines{$topic} > 300) {
 208                 # TODO use formatted line count
 209                 $flags .= "!";
 210                 $any_long = 1;
 211             }
 212             $flags = sprintf("%-2s", $flags);
 213             $out .= ".L \"$topic $flags\"\n";
 214             $out .= "$desc{$topic}\n";
 215         }
 216     }
 217     unless ($any_topic) {
 218         print STDERR "$0: Subject $subj has no topics\n";
 219         exit 1;
 220     }
 221     $out .= ".s1\n"
 222         . ".in 0\n"
 223         . "For info on a particular topic, type \"info <topic>\" where <topic> is\n"
 224         . "one of the topics listed above.\n";
 225     $out .= "Topics marked by * are the most important and should be read by new players.\n"
 226         if $any_basic;
 227     $out .= "Topics marked by + are obsolete.\n"
 228         if $any_obsolete;
 229     $out .= "Topics with unusually long info are marked with a !.\n"
 230         if $any_long;
 231
 232     return if (same_contents($fname, $out));
 233     open(SUBJ, ">$fname")
 234         or die "Can't open $fname for writing: $!";
 235     print SUBJ $out;
 236     close SUBJ;
 237 }
 238
 239 sub same_contents {
 240     my ($fname, $contents) = @_;
 241     local $/;
 242
 243     if (!open(SUBJ, "<$fname")) {
 244         return 0 if ($!{ENOENT});
 245         die "Can't open $fname for reading: $!";
 246     }
 247     my $old = <SUBJ>;
 248     close SUBJ;
 249     return $contents eq $old;
 250 }
 251
 252 # Print an integrity error message and exit with code 1
 253 sub error {
 254     my ($error) = @_;
 255
 256     print STDERR "mksubj.pl:$filename:$.: $error\n";
 257     exit 1;
 258 }