git.pond.sub.org Git - empserver/blob - m4/my_lib_readline.m4

   1 AC_DEFUN([MY_LIB_READLINE], [
   2     have_readline=no
   3     for readline_lib in readline edit editline; do
   4         for termcap_lib in "" termlib termcap curses ncurses; do
   5           AC_CHECK_LIB([$readline_lib], [add_history],
   6               [have_readline=yes; break 2], [], [$termcap_lib])
   7         done
   8     done
   9
  10     if test "$have_readline" = yes; then
  11         AC_CHECK_HEADER([readline/readline.h], [], [have_readline=no],
  12                         [AC_INCLUDES_DEFAULT])
  13         AC_CHECK_HEADER([readline/history.h], [], [have_readline=no],
  14                         [AC_INCLUDES_DEFAULT])
  15     fi
  16
  17     if test "$have_readline" = yes; then
  18         if test "x$termcap_lib" != x; then
  19             LIBS="-l$termcap_lib $LIBS"
  20         fi
  21         LIBS="-l$readline_lib $LIBS"
  22         AC_DEFINE([HAVE_LIBREADLINE], [1],
  23                   [Define if you have libreadline])
  24     fi
  25 ])
  26
  27 AC_DEFUN([MY_WITH_READLINE],
  28 [
  29   AC_ARG_WITH([readline],
  30     [AS_HELP_STRING([--with-readline],
  31       [support fancy command line editing @<:@default=check@:>@])],
  32     [],
  33     [with_readline=check])
  34   if test "x$with_readline" != xno; then
  35       MY_LIB_READLINE
  36       if test "x$have_readline$with_readline" = xnoyes; then
  37           AC_MSG_FAILURE([--with-readline was given, but test for readline failed])
  38       fi
  39       with_readline="$have_readline"
  40   fi])