git.pond.sub.org Git - empserver/blob - src/client/configure.ac

   1 #
   2 #   Empire - A multi-player, client/server Internet based war game.
   3 #   Copyright (C) 1986-2021, Dave Pare, Jeff Bailey, Thomas Ruschak,
   4 #                 Ken Stevens, Steve McClure, Markus Armbruster
   5 #
   6 #   Empire is free software: you can redistribute it and/or modify
   7 #   it under the terms of the GNU General Public License as published by
   8 #   the Free Software Foundation, either version 3 of the License, or
   9 #   (at your option) any later version.
  10 #
  11 #   This program is distributed in the hope that it will be useful,
  12 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 #   GNU General Public License for more details.
  15 #
  16 #   You should have received a copy of the GNU General Public License
  17 #   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 #
  19 #   ---
  20 #
  21 #   See files README, COPYING and CREDITS in the root of the source
  22 #   tree for related information and legal notices.  It is expected
  23 #   that future projects/authors will amend these files as needed.
  24 #
  25 #   ---
  26 #
  27 #   configure.ac: Autoconf input file
  28 #
  29 #   Known contributors to this file:
  30 #      Markus Armbruster, 2005-2020
  31 #
  32 # Process this file with autoconf to produce a configure script.
  33
  34 # Autoconf makes checking for and programming around assorted ancient
  35 # crap relatively painless.  But why bother?  Just rely on C89 and
  36 # POSIX, and when something breaks on some oddball machine, see
  37 # whether it's worth fixing.
  38
  39 AC_PREREQ(2.69)
  40 AC_INIT([Wolfpack Empire Client],
  41         m4_esyscmd([cat .tarball-version]),
  42         [wolfpack@wolfpackempire.com],,
  43         [http://www.wolfpackempire.com/])
  44 AC_CONFIG_SRCDIR([empire.6])
  45 AC_CONFIG_HEADERS([config.h])
  46
  47 AC_DEFINE([_XOPEN_SOURCE], [600],
  48           [Request POSIX-1.2001 with XSI Extension])
  49
  50
  51 ### Checks for programs.
  52 AC_PROG_CC
  53 AC_PROG_INSTALL
  54
  55 # Not a program, but need to check this early
  56 MY_WINDOWS_API
  57
  58
  59 ### Checks for libraries.
  60 LIBS="$LIBS_SOCKETS $LIBS"
  61 AX_LIB_SOCKET_NSL
  62 if test "$Windows_API" = yes; then
  63         AC_LIBOBJ([w32/w32io])
  64         AC_LIBOBJ([w32/w32sockets])
  65 fi
  66 MY_WITH_READLINE
  67
  68
  69 ### Checks for header files.
  70
  71
  72 ### Checks for typedefs, structures, and compiler characteristics.
  73
  74 if test "$Windows_API" = yes; then
  75         CPPFLAGS="$CPPFLAGS -Iw32"
  76         CFLAGS="$CFLAGS -mthreads"
  77 fi
  78
  79
  80 ### Checks for library functions.
  81
  82 AC_CHECK_FUNCS(getaddrinfo)
  83
  84
  85 ### Site configuration
  86
  87 AC_ARG_VAR([EMPIREHOST], [Default host [blitz.wolfpackempire.com]])
  88 test "$EMPIREHOST" || EMPIREHOST=blitz.wolfpackempire.com
  89
  90 AC_ARG_VAR([EMPIREPORT], [Default port [6789]])
  91 test "$EMPIREPORT" || EMPIREPORT=6789
  92
  93 MY_WITH_TERMINFO
  94
  95 ### Output
  96
  97 AC_DEFINE_UNQUOTED(VERSION, "`cat $srcdir/.tarball-version`", [Tarball version])
  98
  99 AC_CONFIG_FILES([Makefile ipglob.c])
 100 AC_OUTPUT
 101
 102 AC_MSG_NOTICE([])
 103 AC_MSG_NOTICE([-= Configuration summary =-])
 104 AC_MSG_NOTICE([      readline: $with_readline])
 105 AC_MSG_NOTICE([      terminfo: $with_terminfo])
 106 AC_MSG_NOTICE([    EMPIREHOST: $EMPIREHOST])
 107 AC_MSG_NOTICE([    EMPIREPORT: $EMPIREPORT])