X-Git-Url: http://git.pond.sub.org/?p=empserver;a=blobdiff_plain;f=configure.ac;h=69102a5fa0c47afcb0085ad1890436eeb07ca303;hp=549ffad4f1d8d83955a48916787d4d163808dc9a;hb=664f640979a53f66823f6ed07988bc2ac5ddd496;hpb=87d08a4584db5686b1584aa8b799059c6a6ecf3b

diff --git a/configure.ac b/configure.ac
index 549ffad4f..69102a5fa 100644
--- a/configure.ac
+++ b/configure.ac
@@ -1,6 +1,6 @@
 #
 #   Empire - A multi-player, client/server Internet based war game.
-#   Copyright (C) 1986-2015, Dave Pare, Jeff Bailey, Thomas Ruschak,
+#   Copyright (C) 1986-2017, Dave Pare, Jeff Bailey, Thomas Ruschak,
 #                 Ken Stevens, Steve McClure, Markus Armbruster
 #
 #   Empire is free software: you can redistribute it and/or modify
@@ -27,7 +27,7 @@
 #   configure.ac: Autoconf input file
 #
 #   Known contributors to this file:
-#      Markus Armbruster, 2005-2015
+#      Markus Armbruster, 2005-2016
 #
 # Process this file with autoconf to produce a configure script.
 
@@ -36,8 +36,10 @@
 # POSIX, and when something breaks on some oddball machine, see
 # whether it's worth fixing.
 
-AC_PREREQ(2.64)
-AC_INIT([Wolfpack Empire], [4.3.34], [wolfpack@wolfpackempire.com], [empire],
+AC_PREREQ(2.69)
+AC_INIT([Wolfpack Empire],
+	m4_esyscmd([build-aux/git-version-gen .tarball-version]),
+	[wolfpack@wolfpackempire.com], [empire],
 	[http://www.wolfpackempire.com/])
 AC_CONFIG_SRCDIR([include/combat.h])
 AC_CONFIG_AUX_DIR([build-aux])
@@ -50,7 +52,6 @@ AC_PROG_AWK
 AC_PROG_INSTALL
 AC_PROG_RANLIB
 AC_PROG_CC
-AC_SUBST(GCC)
 AM_PROG_CC_C_O
 # Private automake macro, tsk, tsk, tsk...
 _AM_DEPENDENCIES(CC)
@@ -59,9 +60,13 @@ AC_ARG_VAR(NROFF, [nroff command])
 AC_CHECK_PROG(NROFF, groff, [GROFF_NO_SGR= groff -Tascii -U], nroff)
 
 # not really a check for a program, but close enough
-if test -d $srcdir/.git; then revctrl=git
+if test -d $srcdir/.git
+then revctrl=git
 else revctrl=
 fi
+if test "$revctrl" && test -r $srcdir/.tarball-version
+then AC_MSG_ERROR([$srcdir/.tarball-version must not exist])
+fi
 AC_SUBST(revctrl,$revctrl)
 
 # Not a program, but need to check this early
@@ -74,6 +79,7 @@ LIBS_util="$LIBS"
 LIBS="$LIBS_SOCKETS $LIBS"
 AX_LIB_SOCKET_NSL
 LIBS_server="$LIBS"
+MY_WITH_READLINE
 
 
 ### Checks for header files
@@ -81,7 +87,82 @@ LIBS_server="$LIBS"
 
 ### Checks for typedefs, structures, and compiler characteristics
 
-AC_C_CHAR_UNSIGNED
+# Enable useful warnings
+# Some of them are commented out because the code needs cleanup first
+# Clang needs to be tested with -Werror=unknown-warning-option
+AX_CHECK_COMPILE_FLAG([-Werror=unknown-warning-option],
+[cflags_test="-Werror=unknown-warning-option"],
+[cflags_test=""])
+MY_APPEND_COMPILE_FLAGS([-Wall -Wextra dnl
+dnl -Wcast-align dnl
+dnl -Wconversion dnl
+-Wdeclaration-after-statement dnl
+dnl -Wformat-nonliteral dnl
+-Wformat-security dnl
+-Winit-self dnl
+-Wlogical-op dnl
+-Wmissing-prototypes dnl
+-Wnested-externs dnl
+-Wold-style-definition dnl
+-Wpacked dnl
+-Wpointer-arith dnl
+-Wredundant-decls dnl
+dnl -Wshadow dnl
+-Wstrict-prototypes dnl
+dnl too prone to false positives: -Wsuggest-attribute=format dnl
+dnl -Wswitch-default dnl
+-Wundef dnl
+-Wno-unused-parameter dnl
+], [], [$cflags_test])
+
+# Our carg() conflicts with libm's TODO clean that up
+MY_APPEND_COMPILE_FLAGS([-fno-builtin-carg -Wno-incompatible-library-redeclaration])
+
+# No multiple definitions of uninitialized global variables
+MY_APPEND_COMPILE_FLAGS([-fno-common])
+
+# Reign in overzealous optimizers
+#
+# Contemporary compilers can squeeze out some extra performance by
+# assuming the program never executes code that has undefined behavior
+# according to the C standard.  Unfortunately, this can break
+# programs.  Pointing out that these programs are non-conforming is as
+# correct as it is unhelpful, at least as long as the compiler is
+# unable to diagnose the non-conformingness.
+#
+# Since keeping our programs working is a lot more important to us
+# than running them as fast as possible, forbid some assumptions that
+# are known to break real-world programs:
+#
+# * Aliasing: perfectly clean programs don't engage in type-punning,
+#   and perfectly conforming programs do it only in full accordance
+#   with the standard's (subtle!) aliasing rules.  Neither kind of
+#   perfection is realistic for us, therefore -fno-strict-aliasing.
+#
+# * Signed integer overflow: perfectly clean programs won't ever do
+#   signed integer arithmetic that overflows.  This is an imperfect
+#   program, therefore -fno-strict-overflow.
+#
+MY_APPEND_COMPILE_FLAGS([dnl
+-fno-strict-aliasing dnl
+-fno-strict-overflow])
+
+# Emit extra code to check for buffer overflows
+# Could fall back to -fstack-protector when -fstack-protector-strong
+# isnt't supported, for users of older compilers.  Doesn't seem worth
+# the trouble, though.
+# Some ports of the GNU toolchain reportedly support it in the
+# compiler, but not libc.  Use a test program that makes the compiler
+# emit the extra stack checking code, and test it compiles and links.
+AX_APPEND_LINK_FLAGS([-fstack-protector-strong], [], [],
+    [AC_LANG_SOURCE([[
+int
+main(int argc, char *argv[])
+{
+    char arr[64], *dst = arr, *src = argv[0];
+    while ((*dst++ = *src++)) ;
+}
+    ]])])
 
 
 ### Checks for library functions
@@ -160,6 +241,7 @@ AC_OUTPUT
 AC_MSG_NOTICE([])
 AC_MSG_NOTICE([-= Configuration summary =-])
 AC_MSG_NOTICE([Thread package: $empthread])
+AC_MSG_NOTICE([      readline: $with_readline])
 AC_MSG_NOTICE([      terminfo: $with_terminfo])
 AC_MSG_NOTICE([    EMPIREHOST: $EMPIREHOST])
 AC_MSG_NOTICE([    EMPIREPORT: $EMPIREPORT])