f4fb8b2a7619525dd1337fd97ce5c662251d3fa7
[eow] / empire.lisp
1 (in-package :empire)
2
3 (defparameter *version* "0.0.1")
4
5 ;;
6 ;; Connection
7 ;;
8
9 (defvar *default-empire-server* "localhost")
10 (defvar *default-empire-server-port* 6665)
11
12 (defvar *last-active-connection* nil)
13
14 (defclass connection ()
15   ((user
16     :initarg :user
17     :accessor user)
18    (password
19     :initarg :password
20     :accessor password
21     :initform nil)
22    (server-name
23     :initarg :server-name
24     :accessor server-name
25     :initform "Unknown server")
26    (server-port
27     :initarg :server-port
28     :accessor server-port
29     :initform *default-empire-server-port*)
30    (socket
31     :initarg :socket
32     :accessor socket
33     :documentation "Slot to store socket (for internal use only).")
34    (stream
35     :initarg :stream
36     :accessor network-stream
37     :documentation "Stream used to talk to the empire server.")
38    (connection-handler
39     :accessor connection-handler
40     :initform nil
41     :documentation "Handler function for incoming messages")
42    (mode
43     :accessor connection-mode
44     :initform nil
45     :documentation "TODO(gefla)")
46    (session
47     :accessor session
48     :initarg :session
49     :documentation "web session to which this connection belongs")
50    (send-queue
51     :accessor send-queue
52     :initform (locked-queue:create)
53     :documentation "lines outstanding to be sent at next prompt")
54    (xdump :accessor xdump :initform (xdump:make-parser))))
55
56 (defun make-connection (&key (user nil)
57                         (password nil)
58                         (server-name *default-empire-server*)
59                         (server-port *default-empire-server-port*)
60                         (socket nil)
61                         (network-stream nil)
62                         session)
63   (make-instance 'connection
64                  :user user
65                  :password password
66                  :server-name server-name
67                  :server-port server-port
68                  :socket socket
69                  :stream network-stream
70                  :session session))
71
72 ;;; interface
73 (defun connect  (&key (user nil)
74                  (password nil)
75                  (server-name *default-empire-server*)
76                  (server-port *default-empire-server-port*)
77                  session)
78   "Connect to server and return a connection object."
79   (let* ((socket (usocket:socket-connect server-name server-port))
80          (stream (usocket:socket-stream socket))
81          (connection (make-connection :user user
82                                       :password password
83                                       :socket socket
84                                       :network-stream stream
85                                       :server-name server-name
86                                       :server-port server-port
87                                       :session session))
88          (handler (spawn-with-name (format nil "empire-handler-~a" user)
89                                    #'handle-connection connection)))
90     (setf (connection-handler connection) handler)
91     (empire-log:info "~a: connect" connection)
92     connection))
93
94 (defgeneric quit (connection))
95 (defgeneric handle-connection (connection))
96 (defgeneric read-message (connection))
97 (defgeneric send-message (connection message &key next-mode))
98 (defgeneric connected-p (connection))
99 (defgeneric reconnect (conncetion))
100
101 (defmethod connected-p ((c connection))
102   (sb-thread:thread-alive-p (connection-handler c)))
103
104 (defmethod reconnect ((c connection))
105   (with-slots (server-name server-port user password socket stream connection-handler) c
106       (let* ((sock (usocket:socket-connect server-name server-port))
107              (s (usocket:socket-stream sock)))
108         (setf socket sock
109               stream s
110               connection-handler (spawn-with-name (format nil "empire-handler-~a" user)
111                                                   #'handle-connection c))))
112   (empire-log:info "~a: reconnect" c))
113
114 (defparameter +C_CMDOK+ "0")
115 (defparameter +C_DATA+ "1")
116 (defparameter +C_INIT+ "2")
117 (defparameter +C_EXIT+ "3")
118 (defparameter +C_FLUSH+ "4")
119 (defparameter +C_NOECHO+ "5")
120 (defparameter +C_PROMPT+ "6")
121 (defparameter +C_ABORT+ "7")
122 (defparameter +C_REDIR+ "8")
123 (defparameter +C_PIPE+ "9")
124 (defparameter +C_CMDERR+ "a")
125 (defparameter +C_BADCMD+ "b")
126 (defparameter +C_EXECUTE+ "c")
127 (defparameter +C_FLASH+ "d")
128 (defparameter +C_INFORM+ "e")
129
130 (defclass base-mode ()
131   ((connection :initarg :connection :accessor connection)))
132 (defclass init-mode (base-mode)
133   ((phase :initform :initial
134           :documentation "Initialization phase")))
135 (defclass play-mode (base-mode) nil)
136
137 (defun make-mode (connection mode)
138   (make-instance mode :connection connection))
139
140 (defgeneric set-new-mode (base-mode new-mode))
141 (defmethod set-new-mode ((m base-mode) new-mode)
142   (let* ((c (connection m))
143          (mode (make-mode c new-mode)))
144     (empire-log:info "~a: set-new-mode ~a -> ~a" c (connection-mode c) new-mode)
145     (setf (connection-mode c) mode)))
146
147 (defgeneric handle-cmdok (base-mode message))
148 (defgeneric handle-data (base-mode message))
149 (defgeneric handle-init (base-mode message))
150 (defgeneric handle-exit (base-mode message))
151 (defgeneric handle-prompt (base-mode message))
152 (defgeneric handle-flush (base-mode message))
153 (defgeneric handle-simple-message (base-mode message))
154 (defgeneric handle-ignore (base-mode message))
155
156 (defmethod handle-init ((m init-mode) message)
157   (declare (ignorable message))
158   (with-slots (phase connection) m
159     (ecase phase
160       (:initial (handle-cmdok m message))
161       (:play-sent (set-new-mode m 'play-mode)))))
162
163 (defmethod handle-cmdok ((m init-mode) message)
164   (declare (ignorable message))
165   (with-slots (phase connection) m
166     (flet ((init-phase (mode send-args next-phase)
167              (with-slots (phase connection) mode
168                (send-message-one connection (apply #'format nil send-args))
169                (setf phase next-phase))))
170       (with-slots (user password) (connection m)
171         (ecase phase
172           (:initial (init-phase m `("client eow ~a" ,*version*) :client-sent))
173           (:client-sent (init-phase m `("coun ~a" ,user) :coun-sent))
174           (:coun-sent (init-phase m `("pass ~a" ,password) :pass-sent))
175           (:pass-sent (init-phase m '("play") :play-sent)))))))
176
177 (defmethod handle-exit ((m init-mode) message)
178   (declare (ignorable message))
179   (with-slots (phase connection) m
180     (ecase phase
181       (:play-sent (send-message-one connection "kill")
182                   (setf phase :kill-sent))
183       (:kill-sent (send-message-one connection "play")
184                   (setf phase :play-sent)))))
185
186 (defmethod handle-data ((m init-mode) message)
187   (declare (ignorable message))
188   t)
189
190 (defmethod handle-exit ((m play-mode) message)
191   (declare (ignorable message))
192   (quit (connection m)))
193
194 (defmethod handle-data ((m play-mode) message)
195   (let* ((c (connection m)))
196     (empire-web:data (session c) message)))
197
198 (defmethod handle-simple-message ((m play-mode) message)
199   (let* ((c (connection m)))
200     (empire-web:data (session c) message)))
201
202 (defmethod handle-flush ((m play-mode) message)
203   (let* ((c (connection m)))
204     (empire-web:prompt (session c) message)
205     (send-next-line c)))
206
207 (defmethod send-next-line ((c connection))
208   (let ((next-event (locked-queue:dequeue (send-queue c))))
209     (etypecase next-event
210       (string (send-message-one c next-event))
211       (cons (let ((message (car next-event))
212                   (mode (cdr next-event)))
213               (send-message-one c message)
214               (set-new-mode (connection-mode c) mode))))))
215
216 (defun read-no-eval (stream)
217   (let ((*read-eval* nil))
218     (read stream)))
219
220 (defmethod handle-prompt ((m play-mode) message)
221   (let* ((c (connection m)))
222     (with-input-from-string (s message)
223       (let* ((minutes (read-no-eval s))
224              (btus (read-no-eval s)))
225         (empire-web:prompt (session c)
226                            (format nil "[~a,~a]: " minutes btus))))
227     (send-next-line c)))
228
229 (defmethod handle-ignore ((m init-mode) message)
230   (declare (ignorable message))
231   t)
232
233 (defparameter *line-type-dispatch*
234   (list `(,+C_DATA+ . handle-data)
235         `(,+C_INIT+ . handle-init)
236         `(,+C_EXIT+ . handle-exit)
237         `(,+C_FLUSH+ . handle-flush)
238         `(,+C_BADCMD+ . handle-simple-message)
239         `(,+C_FLASH+ . handle-simple-message)
240         `(,+C_CMDOK+ . handle-cmdok)
241         `(,+C_PROMPT+ . handle-prompt)))
242
243 (defun parse-server-line (line)
244   (let* ((first-space-index
245           (loop for i from 0 below (length line)
246              if (eq (char line i) #\Space)
247              do (return i)))
248          (message-type (subseq line 0 first-space-index))
249          (message (if first-space-index
250                       (subseq line (+ first-space-index 1))
251                       "")))
252     (values message message-type)))
253
254 (defmethod handle-connection ((c connection))
255   (setf (connection-mode c) (make-mode c 'init-mode))
256   (loop while (read-message c)))
257
258 (defun lookup-handler (message-type)
259   (cdr (assoc message-type *line-type-dispatch* :test 'string=)))
260
261 (define-condition no-handler (error)
262   ((mode :initarg :mode)
263    (type :initarg :type))
264   (:report (lambda (condition stream)
265              (with-slots (mode type) condition
266                (format stream "No handler for ~a in mode ~a."
267                        type mode)))))
268 (defmethod read-message ((c connection))
269   (handler-case
270       (let* ((s (network-stream c))
271              (line (read-line s)))
272         (empire-log:info "~a: < ~a" c line)
273         (setf *last-active-connection* c)
274         (multiple-value-bind (message type) (parse-server-line line)
275           (let ((handler (lookup-handler type))
276                 (mode (connection-mode c)))
277             (if handler
278                 (funcall handler mode message)
279                 (error 'no-handler :mode mode :type type))))
280         line)
281     (sb-int:closed-stream-error () nil)
282     (sb-int:simple-stream-error () nil)
283     (end-of-file () nil)))
284
285 (defun raw-send-message (s message)
286     (write-sequence message s)
287     (terpri s)
288     (force-output s))
289
290 (defgeneric send-message-one (connection string))
291 (defmethod send-message-one ((c connection) message)
292   (empire-log:info "~a: > ~a" c message)
293   (setf *last-active-connection* c)
294   (let ((s (network-stream c)))
295     (raw-send-message s message)))
296
297 (defmethod send-message ((c connection) message &key next-mode)
298   (if (not (connected-p c))
299       (reconnect c))
300   (if next-mode
301       (locked-queue:enqueue (send-queue c) (cons message next-mode))
302       (locked-queue:enqueue (send-queue c) message)))
303
304 (defparameter +special-command-char+ #\;)
305
306 (defun special-command-p (line)
307   (and (> (length line) 0)
308        (char= +special-command-char+ (aref line 0))))
309
310 (defclass xdump-mode (play-mode)
311   ((phase :initform :meta-meta)
312    (dump-queue :initform nil)
313    (dump-index :initform 0)))
314
315 (defmethod handle-data ((m xdump-mode) message)
316   (with-slots (connection phase dump-queue dump-index) m
317     (xdump:with-parser (xdump connection)
318       (if (xdump:parse-line (xdump connection) message)
319           ;;XXX consider something like a 'pop-mode function
320           (ccase phase
321             (:meta-meta 
322              (setf phase :meta-table)
323              (send-message connection "xdump meta table"))
324             (:meta-table
325              (setf phase :table-table)
326              (send-message connection "xdump table *"))
327             (:table-table
328              (setf phase :meta-type)
329              (send-message connection "xdump meta meta-type"))
330             (:meta-type
331              (setf phase :type-table)
332              (send-message connection "xdump meta-type *"))
333             (:type-table
334              (setf phase :tables-meta
335                    dump-queue (xdump::table-entries (xdump:table "table"))
336                    dump-index 0)
337              (send-message connection (format nil "xdump meta ~a" (xdump-data:name (aref dump-queue 0)))))
338             (:tables-meta
339              (setf phase :tables-content)
340              (send-message connection (format nil "xdump ~a *" (xdump-data:name (aref dump-queue dump-index)))))
341             (:tables-content
342              (if (< dump-index (fill-pointer dump-queue))
343                  (progn (setf phase :tables-meta)
344                         (incf dump-index)
345                         (loop while (and (< dump-index (fill-pointer dump-queue))
346                                          (let ((dump-queue-entry (aref dump-queue dump-index)))
347                                            (or (null dump-queue-entry)
348                                                (string= "meta"
349                                                         (xdump-data:name dump-queue-entry)))))
350                            do (incf dump-index))
351                         (if (and (<= dump-index (fill-pointer dump-queue))
352                                  (not (null (aref dump-queue dump-index))))
353                             (send-message connection (format nil "xdump meta ~a" (xdump-data:name (aref dump-queue dump-index))))))
354                  (progn
355                    (xdump:checkpoint)
356                    (set-new-mode (connection-mode connection) 'play-mode)))))))))
357
358 (defmethod special-xup ((c connection))
359   (let ((user-log (empire-log:open-user-log (user c))))
360     (setf (xdump c) (xdump:make-parser :user-log user-log))
361     (send-message c "xdump meta meta" :next-mode 'xdump-mode)))
362
363 (defmethod special-command ((c connection) line)
364   (cond ((string= line "xup") (special-xup c))
365         (t (empire-web:data (session c) "Unknown special command")))
366   line)
367
368 (defmethod command ((c connection) line)
369   (cond ((special-command-p line) (special-command c (subseq line 1)))
370         (t (send-message c line))))
371
372 (defmethod quit ((c connection))
373   (usocket:socket-close (socket c)))