git.pond.sub.org Git - eow/blob - xdump.lisp

   1 (in-package :xdump)
   2
   3 (defvar *current-parser* nil)
   4
   5 (defclass table-column-meta ()
   6   ((name :accessor meta-name)
   7    (type :accessor meta-type)
   8    (flags :accessor meta-flags)
   9    (len :accessor meta-len)
  10    (table :accessor meta-table)))
  11
  12 (defclass xdump-table ()
  13   ((name :accessor table-name :initarg :name)
  14    (index :accessor table-index :initarg :index)
  15    (last-update :accessor table-last-update :initform 0)
  16    (entry-class :accessor table-entry-class :initarg :entry-class)
  17    (entries :accessor table-entries
  18             :initform (make-array 8
  19                                   :fill-pointer 0
  20                                   :adjustable t
  21                                   :initial-element nil))
  22    (has-uid-p :accessor has-uid-p :initarg :has-uid-p)))
  23
  24 (defclass xdump-parser ()
  25   ((line-parser :accessor line-parser :initform nil)
  26    (entry-buffer :accessor entry-buffer
  27                  :initform (make-array 1 :fill-pointer 0 :adjustable t))
  28    (entry-index :accessor entry-index :initform 0)
  29    (finalizer :accessor finalizer :initform nil)
  30    (name :accessor table-name :initform nil)
  31    (timestamp :accessor timestamp :initform nil)
  32    (meta-by-index :accessor meta-by-index
  33                   :initform (make-array 128
  34                                         :adjustable t
  35                                         :initial-element nil))
  36    (table-by-index :accessor table-by-index
  37                    :initform (make-array 128
  38                                          :adjustable t
  39                                          :initial-element nil))
  40    (table-classes-package :accessor table-classes-package
  41                           :initform (make-package (gensym)))
  42    (index-by-name :accessor index-by-name
  43                   :initform (make-hash-table :size 128 :test 'equal))
  44    (meta-index :accessor meta-index :initform (make-array 5))
  45    (meta-meta :accessor meta-meta :initform (make-array 5))))
  46
  47 (defgeneric get-table (xdump-parser table-name))
  48 (defgeneric get-table-entry (xdump-parser table-name index))
  49 (defgeneric sym-by-value (xdump-parser table-name value))
  50 (defgeneric array-p (xdump-parser column))
  51 (defgeneric finish-table (xdump-parser number-of-records))
  52 (defgeneric parse-entry (xdump-parser line))
  53 (defgeneric parse-meta (xdump-parser name timestamp))
  54 (defgeneric parse-table (xdump-parser name timestamp))
  55 (defgeneric header-parser (xdump-parser line))
  56 (defgeneric parse-line (xdump-parser line))
  57 (defgeneric reset-table-parser (xdump-parser))
  58 (defgeneric entry-from-vector (xdump-parser class meta-table entry-vector
  59                                             &key array-support-p))
  60
  61 (defmethod get-table ((parser xdump-parser) table-name)
  62   (with-slots (index-by-name table-by-index) parser
  63     (let* ((table-index (gethash table-name index-by-name))
  64            (table (aref table-by-index table-index)))
  65       table)))
  66
  67 (defmacro with-parser (parser &body body)
  68   `(let ((*current-parser* ,parser))
  69      ,@body))
  70
  71 (defun table (table-name &optional (parser *current-parser*))
  72   (get-table parser table-name))
  73
  74 (defmethod get-table-entry ((parser xdump-parser) table-name index)
  75     (aref (table-entries (get-table table-name)) index))
  76
  77 (defmethod sym-by-value ((parser xdump-parser) table-name value)
  78   (with-slots (table-classes-package) parser
  79     (let ((value-slot (find-symbol "VALUE" table-classes-package))
  80           (name-slot (find-symbol "NAME" table-classes-package))
  81           (meta-type-table (get-table parser table-name)))
  82       (loop for entry across (table-entries meta-type-table)
  83            if (= (slot-value entry value-slot) value)
  84            return (slot-value entry name-slot)))))
  85
  86 (defmethod reset-table-parser ((parser xdump-parser))
  87   (with-slots (line-parser entry-buffer entry-index finalizer name timestamp)
  88       parser
  89     (setf line-parser #'header-parser
  90           entry-buffer (make-array 1 :fill-pointer 0 :adjustable t)
  91           entry-index 0
  92           finalizer nil
  93           name nil
  94           timestamp nil)))
  95
  96 (defun meta-meta-finalizer (parser)
  97   (with-slots (entry-buffer meta-index meta-meta) parser
  98                                         ; build meta-index from integer index to
  99                                         ; slot symbol
 100     (loop
 101        for i = 0 then (+ i 1)
 102        for e across entry-buffer
 103        do (let* ((slot-name (string-upcase (car e)))
 104                  (slot (find-symbol slot-name :xdump)))
 105             (setf (aref meta-index i) slot)))
 106                                         ; build meta-meta table
 107     (loop for entry across entry-buffer
 108        for i = 0 then (+ i 1)
 109        do (let ((meta-meta-column (make-instance 'table-column-meta)))
 110             (loop for slot across meta-index
 111                for field in entry
 112                do (setf (slot-value meta-meta-column slot) field))
 113             (setf (aref meta-meta i) meta-meta-column)))))
 114
 115 (defun table-entry-defclass-form (name class-name package slot-list)
 116   `(defclass ,(find-symbol class-name package) ()
 117      ,(mapcar #'(lambda (raw-slot-name)
 118                   (let* ((slot-name (string-upcase raw-slot-name))
 119                          (accessor-name (string-upcase (format nil "~a-~a"
 120                                                                name
 121                                                                slot-name))))
 122                     (list (intern slot-name package)
 123                           :accessor (intern accessor-name package))))
 124               slot-list)))
 125
 126 (defun meta-finalizer (parser)
 127   (let ((meta-table (make-array 1 :fill-pointer 0 :adjustable t)))
 128     (with-slots (entry-buffer name meta-index meta-by-index index-by-name
 129                               table-by-index)
 130         parser
 131       (loop for entry across entry-buffer
 132          do (let ((meta (make-instance 'table-column-meta)))
 133               (loop for slot across meta-index
 134                  for field in entry
 135                  do (setf (slot-value meta slot) field))
 136               (vector-push-extend meta meta-table)))
 137       (format t "~a~%~a~%~a~%" name meta-table entry-buffer)
 138       (let ((table-index (if (string= "table" name)
 139                              ; voodoo: the first column of the table of tables
 140                              ; is the uid
 141                              (elt (aref entry-buffer 0) 4)
 142                              (gethash name index-by-name)))
 143             (has-uid-p nil))
 144         (setf (aref meta-by-index table-index) meta-table)
 145
 146         ;; determine if this table has a uid column
 147         (if (and (string= "uid" (elt (aref entry-buffer 0) 0))
 148                  (eql (elt (aref entry-buffer 0) 4) table-index))
 149             (setf has-uid-p t))
 150
 151         ;; create xdump-table instance and entry class
 152         (let* ((class-name (string-upcase (format nil "~a-table-entry" name)))
 153                (package (table-classes-package parser))
 154                (table-instance (make-instance 'xdump-table
 155                                               :name name
 156                                               :index table-index
 157                                               :entry-class (intern class-name
 158                                                                    package)
 159                                               :has-uid-p has-uid-p))
 160                (slot-list (loop for entry across entry-buffer
 161                              collect (car entry))))
 162           (setf (aref table-by-index table-index) table-instance)
 163           (format t "slot-list: ~a~%" slot-list)
 164           (eval (table-entry-defclass-form name class-name package
 165                                            slot-list)))))))
 166
 167 (defmethod array-p ((parser xdump-parser) column)
 168   (let ((column-len (meta-len column))
 169         (column-type (sym-by-value parser "meta-type" (meta-type column))))
 170     (and (> column-len 0)
 171          (not (string= column-type "c")))))
 172
 173 (defmethod entry-from-vector (parser class meta-table entry-vector
 174                               &key (array-support-p t))
 175   (with-slots (table-classes-package) parser
 176     (let ((new-entry (make-instance class))
 177           (entries entry-vector))
 178       (loop
 179          for column across meta-table do
 180            (let ((slot (find-symbol (string-upcase (meta-name column))
 181                                     table-classes-package)))
 182              (if (and array-support-p (array-p parser column))
 183                  ;; then collect array
 184                  (let ((array nil))
 185                    (dotimes (j (meta-len column))
 186                      (push (pop entries) array))
 187                    (setf (slot-value new-entry slot) array))
 188                  ;; else collect single entry
 189                  (progn
 190                    (setf (slot-value new-entry slot) (pop entries))))))
 191       new-entry)))
 192
 193 (defmethod table-entry-insert-at ((table xdump-table) entry index)
 194                                         ; extend array if necessary
 195   (let ((entries (table-entries table)))
 196     (unless (> (fill-pointer entries) index)
 197       (adjust-array entries (max 1 (* 2 index))
 198                     :fill-pointer index
 199                     :initial-element nil))
 200     (setf (aref entries index) entry)))
 201
 202 (defun table-finalizer (parser)
 203   (with-slots (entry-buffer name timestamp index-by-name meta-by-index
 204                             table-by-index table-classes-package) parser
 205     (if (string= name "table") ; special magic: prefill index-by-name
 206         (loop for entry across entry-buffer do
 207              (setf (gethash (second entry) index-by-name) (first entry))))
 208     (format t "table-finalizer: ~a~%" name)
 209     (let* ((table-index (gethash name index-by-name))
 210            (meta-table (aref meta-by-index table-index))
 211            (table (aref table-by-index table-index))
 212            (has-uid-p (has-uid-p table))
 213            (array-support-p (not (or (string= name "table")
 214                                      (string= name "meta-type")))))
 215       (loop for entry across entry-buffer do
 216            (let ((entry-instance (entry-from-vector parser
 217                                                     (table-entry-class table)
 218                                                     meta-table
 219                                                     entry
 220                                                     :array-support-p
 221                                                     array-support-p)))
 222              (if has-uid-p
 223                  (let ((index (first entry)))
 224                    (table-entry-insert-at table entry-instance index))
 225                  (vector-push-extend entry-instance (table-entries table)))))
 226       (setf (table-last-update table) timestamp))))
 227
 228 (defmethod finish-table ((parser xdump-parser) number-of-records)
 229   (if (not (equal number-of-records (length (entry-buffer parser))))
 230       (error "Table row count mismatch"))
 231   (funcall (finalizer parser) parser)
 232   (reset-table-parser parser)
 233   t) ;; finished
 234
 235 (defmethod parse-entry ((parser xdump-parser) line)
 236   (if (char= #\/ (aref line 0))
 237       (finish-table parser (parse-integer (subseq line 1)))
 238       (let ((fields (mapcar #'read-from-string (cl-ppcre:split " " line))))
 239         (with-slots (entry-buffer entry-index) parser
 240           (vector-push-extend fields entry-buffer)
 241           (incf entry-index))
 242         nil)))
 243
 244 (defmethod parse-meta ((parser xdump-parser) input-name input-timestamp)
 245   (with-slots (line-parser finalizer name timestamp) parser
 246     (setf line-parser #'parse-entry
 247           finalizer (if (string= "meta" input-name)
 248                         #'meta-meta-finalizer
 249                         #'meta-finalizer)
 250           name input-name
 251           timestamp input-timestamp)))
 252
 253 (defmethod parse-table ((parser xdump-parser) input-name input-timestamp)
 254   "Parse a normal table.
 255
 256    Args:
 257      parser: The current parser
 258      input-name: Name of the current table
 259      input-timestamp: Timestamp of the current table"
 260   (with-slots (line-parser finalizer name timestamp) parser
 261     (setf line-parser #'parse-entry
 262           finalizer #'table-finalizer
 263           name input-name
 264           timestamp input-timestamp)))
 265
 266 (defmethod header-parser ((parser xdump-parser) line)
 267   (multiple-value-bind (fullmatch groups)
 268       (cl-ppcre:scan-to-strings "^XDUMP meta (.*) ([0-9]+)$" line)
 269     (if fullmatch
 270         ;; meta table
 271         (let ((name (aref groups 0))
 272               (timestamp (parse-integer (aref groups 1))))
 273           (parse-meta parser name timestamp))
 274         ;; table
 275         (multiple-value-bind (fullmatch groups)
 276             (cl-ppcre:scan-to-strings "^XDUMP (.*) ([0-9]+)$" line)
 277           (declare (ignorable fullmatch))
 278           (let ((name (aref groups 0))
 279                 (timestamp (parse-integer (aref groups 1))))
 280             (parse-table parser name timestamp)))))
 281   nil)
 282
 283 (defun make-parser ()
 284   (let ((parser (make-instance 'xdump-parser)))
 285     (setf (line-parser parser) #'header-parser)
 286     parser))
 287
 288 (defmethod parse-line ((parser xdump-parser) line)
 289   (with-slots (line-parser) parser
 290     (funcall line-parser parser line)))
 291
 292 (defmethod parse-stream ((parser xdump-parser) stream)
 293   (loop for line = (read-line stream nil)
 294      while line do (parse-line parser line)))
 295
 296 (defmethod parse-file ((parser xdump-parser) filename)
 297   (with-open-file (s filename)
 298     (parse-stream parser s)))
 299
 300 (defun t1 ()
 301   (let ((parser (make-parser)))
 302     (setf *current-parser* parser)
 303     (parse-file parser "testdata/xdump-meta-meta.txt")))
 304
 305 (defun t2 ()
 306   (let ((parser (make-parser)))
 307     (setf *current-parser* parser)
 308     (parse-file parser "testdata/xdump-meta-meta.txt")
 309     (parse-file parser "testdata/xdump-meta-table.txt")
 310     (parse-file parser "testdata/xdump-table.txt")
 311     (parse-file parser "testdata/xdump-meta-34.txt")
 312     (parse-file parser "testdata/xdump-34.txt")))