(in-package :empire-web)

(declaim (optimize (space 0) (speed 0) (safety 3) (debug 3)))


(defvar *this-file* (load-time-value
                     (or #.*compile-file-pathname* *load-pathname*)))

(defvar *this-dir* (make-pathname :host (pathname-host *this-file*)
                                  :device (pathname-device *this-file*)
                                  :directory (pathname-directory *this-file*)))

(defparameter +templates-root+ (namestring *this-dir*))
(defparameter +root-url+ "/eow/")
(defparameter +web-root-base+ "/eow")
(defparameter +web-root+ (concatenate 'string +web-root-base+ "/"))
(defparameter +static-web-root+ (concatenate 'string +web-root+ "static/"))
(defparameter +static-files-root+ (concatenate 'string +templates-root+ "static/"))
(defparameter +login-page+ (concatenate 'string +static-web-root+ "login.html"))
(defparameter +root-page-file+ "root.html")

(defun string-starts-with (string prefix)
  ;; (from Hunchentoot)
  (let ((mismatch (mismatch string prefix :test #'char=)))
    (or (null mismatch)
        (>= mismatch (length prefix)))))

(defun serve-static ()
  "Handle a request for a file under static/ directory"
  (let* ((script-name (script-name))
         (fname (subseq script-name (length +static-web-root+)))
         (fullname (concatenate 'string +static-files-root+ fname)))
    (handle-static-file fullname)))

(defclass session ()
  ((update-queue
    :accessor update-queue
    :initform (locked-queue:create)
    :documentation "Updates to be sent to the browser")
   (connection
   :accessor connection
   :documentation "Connection to the empire game server")))

(defun make-session (username password)
  (let* ((session (make-instance 'session))
	 (connection (empire:connect :user username
				     :password password
				     :session session)))
    (setf (slot-value session 'connection) connection)
    session))

(defgeneric send (session string))
(defgeneric prompt (session string))
(defgeneric data (session message))

(defvar *empire-session*)

(defmacro with-session (&body body)
  `(let ((*empire-session* (session-value 'session)))
     (if *empire-session*
	 (progn ,@body)
	 (redirect +login-page+))))

(defun update ()
  "Send stream of updates to client"
  (with-session
    (locked-queue:dequeue (update-queue *empire-session*))))

(defmethod send ((s session) string)
  "Push a javascript update fragment to the client."
  (locked-queue:enqueue (update-queue s) string))

(defmethod prompt ((s session) p)
  (send s (parenscript:ps* `(prompt ,p))))

(defmethod data ((s session) message)
  (send s (parenscript:ps* `(msg ,message))))

;; destination of login-form
(defun login-action ()
  (handler-case
      (let* ((user (post-parameter "username"))
	     (pass (post-parameter "password"))
	     (session (make-session user pass)))
	(setf (session-value 'session) session)
	(empire-log:info "User ~a logging in. Session ~a" user session)
	(redirect +root-url+))
    (usocket:connection-refused-error (e)
      (format nil "Connection error: ~a~%" e))))

(defun command-action ()
  (with-session
      (empire:send-message (connection *empire-session*) (get-parameter "q"))))

(defun root-page ()
  (with-session
    (handle-static-file (concatenate 'string +static-files-root+ +root-page-file+))))

(defun dispatch (request)
  (let ((script-name (script-name request)))
    (cond
      ((not (string-starts-with script-name +web-root+)) nil) ; do not handle this request
      ((string= script-name "/eow/update") 'update)
      ((string= script-name "/eow/login") 'login-action)
      ((string= script-name "/eow/command") 'command-action)
      ((or (string-equal script-name +web-root-base+)
           (string-equal script-name +web-root+)) 'root-page) ; go to the start page
      ((string-starts-with script-name +static-web-root+) 'serve-static)))) ; serve static file


(defun start ()
  (empire-log:info "Startup")
  (pushnew 'dispatch *dispatch-table* :test #'eq))