(in-package :xdump)

(defvar *current-parser* nil)

(defclass table-column-meta ()
  ((name :accessor meta-name)
   (type :accessor meta-type)
   (flags :accessor meta-flags)
   (len :accessor meta-len)
   (table :accessor meta-table)))

(defclass xdump-table ()
  ((name :accessor table-name :initarg :name)
   (index :accessor table-index :initarg :index)
   (last-update :accessor table-last-update :initform 0)
   (entry-class :accessor table-entry-class :initarg :entry-class)
   (entries :accessor table-entries
	    :initform (make-array 8
				  :fill-pointer 0
				  :adjustable t
				  :initial-element nil))
   (has-uid-p :accessor has-uid-p :initarg :has-uid-p)))

(defun get-table (table-name)
  (let* ((table-index (gethash table-name *index-by-name*))
	 (table (aref *table-by-index* table-index)))
    table))

(defun get-table-entry (table-name index)
    (aref (table-entries (get-table table-name)) index))

(defclass xdump-parser ()
  ((line-parser :accessor line-parser :initform nil)
   (entry-buffer :accessor entry-buffer
		 :initform (make-array 1 :fill-pointer 0 :adjustable t))
   (entry-index :accessor entry-index :initform 0)
   (finalizer :accessor finalizer :initform nil)
   (name :accessor table-name :initform nil)
   (timestamp :accessor timestamp :initform nil)
   (meta-by-index :accessor meta-by-index
		  :initform (make-array 128
					:adjustable t
					:initial-element nil))
   (table-by-index :accessor table-by-index
		   :initform (make-array 128
					 :adjustable t
					 :initial-element nil))
   (table-classes-package :accessor table-classes-package
			  :initform (make-package (gensym)))
   (index-by-name :accessor index-by-name
		  :initform (make-hash-table :size 128 :test 'equal))
   (meta-index :accessor meta-index :initform (make-array 5))
   (meta-meta :accessor meta-meta :initform (make-array 5))))

(defgeneric finish-table (xdump-parser number-of-records))
(defgeneric parse-entry (xdump-parser line))
(defgeneric parse-meta (xdump-parser name timestamp))
(defgeneric parse-table (xdump-parser name timestamp))
(defgeneric header-parser (xdump-parser line))
(defgeneric parse-line (xdump-parser line))
(defgeneric reset-table-parser (xdump-parser))

(defmethod reset-table-parser ((parser xdump-parser))
  (with-slots (line-parser entry-buffer entry-index finalizer name timestamp)
      parser
    (setf line-parser #'header-parser
	  entry-buffer (make-array 1 :fill-pointer 0 :adjustable t)
	  entry-index 0
	  finalizer nil
	  name nil
	  timestamp nil)))

(defun meta-meta-finalizer (parser)
  (with-slots (entry-buffer meta-index meta-meta) parser
					; build meta-index from integer index to
					; slot symbol
    (loop
       for i = 0 then (+ i 1)
       for e across entry-buffer
       do (let* ((slot-name (string-upcase (car e)))
		 (slot (find-symbol slot-name :xdump)))
	    (setf (aref meta-index i) slot)))
					; build meta-meta table
    (loop for entry across entry-buffer
       for i = 0 then (+ i 1)
       do (let ((meta-meta-column (make-instance 'table-column-meta)))
	    (loop for slot across meta-index
	       for field in entry
	       do (setf (slot-value meta-meta-column slot) field))
	    (setf (aref meta-meta i) meta-meta-column)))))

(defun table-entry-defclass-form (name class-name package slot-list)
  `(defclass ,(find-symbol class-name package) ()
     ,(mapcar #'(lambda (raw-slot-name)
		  (let* ((slot-name (string-upcase raw-slot-name))
			 (accessor-name (string-upcase (format nil "~a-~a"
							       name
							       slot-name))))
		    (list (intern slot-name package)
			  :accessor (intern accessor-name package))))
	      slot-list)))

(defun meta-finalizer (parser)
  (let ((meta-table (make-array 1 :fill-pointer 0 :adjustable t)))
    (with-slots (entry-buffer name meta-index meta-by-index index-by-name
			      table-by-index)
	parser
      (loop for entry across entry-buffer
	 do (let ((meta (make-instance 'table-column-meta)))
	      (loop for slot across meta-index
		 for field in entry
		 do (setf (slot-value meta slot) field))
	      (vector-push-extend meta meta-table)))
      (format t "~a~%~a~%~a~%" name meta-table entry-buffer)
      (let ((table-index (if (string= "table" name)
			     ; voodoo: the first column of the table of tables
			     ; is the uid
			     (elt (aref entry-buffer 0) 4)
			     (gethash name index-by-name)))
	    (has-uid-p nil))
	(setf (aref meta-by-index table-index) meta-table)

	;; determine if this table has a uid column
	(if (and (string= "uid" (elt (aref entry-buffer 0) 0))
		 (eql (elt (aref entry-buffer 0) 4) table-index))
	    (setf has-uid-p t))

	;; create xdump-table instance and entry class
	(let* ((class-name (string-upcase (format nil "~a-table-entry" name)))
	       (package (table-classes-package parser))
	       (table-instance (make-instance 'xdump-table
					      :name name
					      :index table-index
					      :entry-class (intern class-name
								   package)
					      :has-uid-p has-uid-p))
	       (slot-list (loop for entry across entry-buffer
			     collect (car entry))))
	  (setf (aref table-by-index table-index) table-instance)
	  (format t "slot-list: ~a~%" slot-list)
	  (eval (table-entry-defclass-form name class-name package
					   slot-list)))))))

(defun entry-from-vector (class meta-table entry-vector table-classes-package)
  (let ((new-entry (make-instance class)))
    (loop
       for item in entry-vector
       for column across meta-table do
	 (let ((slot (find-symbol (string-upcase (meta-name column))
				  table-classes-package)))
	   (setf (slot-value new-entry slot) item)))
    new-entry))

(defmethod table-entry-insert-at ((table xdump-table) entry index)
					; extend array if necessary
  (let ((entries (table-entries table)))
    (unless (> (fill-pointer entries) index)
      (adjust-array entries (max 1 (* 2 index))
		    :fill-pointer index
		    :initial-element nil))
    (setf (aref entries index) entry)))

(defun table-finalizer (parser)
  (with-slots (entry-buffer name timestamp index-by-name meta-by-index
			    table-by-index table-classes-package) parser
    (if (string= name "table") ; special magic: prefill index-by-name
	(loop for entry across entry-buffer do
	     (setf (gethash (second entry) index-by-name) (first entry))))
    (format t "table-finalizer: ~a~%" name)
    (let* ((table-index (gethash name index-by-name))
	   (meta-table (aref meta-by-index table-index))
	   (table (aref table-by-index table-index))
	   (has-uid-p (has-uid-p table)))
      (loop for entry across entry-buffer do
	   (let ((entry-instance (entry-from-vector (table-entry-class table)
						    meta-table
						    entry
						    table-classes-package)))
	     (if has-uid-p
		 (let ((index (first entry)))
		   (table-entry-insert-at table entry-instance index))
		 (vector-push-extend entry-instance (table-entries table)))))
      (setf (table-last-update table) timestamp))))

(defmethod finish-table ((parser xdump-parser) number-of-records)
  (if (not (equal number-of-records (length (entry-buffer parser))))
      (error "Table row count mismatch"))
  (funcall (finalizer parser) parser)
  (reset-table-parser parser)
  t) ;; finished

(defmethod parse-entry ((parser xdump-parser) line)
  (if (char= #\/ (aref line 0))
      (finish-table parser (parse-integer (subseq line 1)))
      (let ((fields (mapcar #'read-from-string (cl-ppcre:split " " line))))
	(with-slots (entry-buffer entry-index) parser
	  (vector-push-extend fields entry-buffer)
	  (incf entry-index))
	nil)))

(defmethod parse-meta ((parser xdump-parser) input-name input-timestamp)
  (with-slots (line-parser finalizer name timestamp) parser
    (setf line-parser #'parse-entry
	  finalizer (if (string= "meta" input-name)
			#'meta-meta-finalizer
			#'meta-finalizer)
	  name input-name
	  timestamp input-timestamp)))

(defmethod parse-table ((parser xdump-parser) input-name input-timestamp)
  "Parse a normal table.

   Args:
     parser: The current parser
     input-name: Name of the current table
     input-timestamp: Timestamp of the current table"
  (with-slots (line-parser finalizer name timestamp) parser
    (setf line-parser #'parse-entry
	  finalizer #'table-finalizer
	  name input-name
	  timestamp input-timestamp)))

(defmethod header-parser ((parser xdump-parser) line)
  (multiple-value-bind (fullmatch groups)
      (cl-ppcre:scan-to-strings "^XDUMP meta (.*) ([0-9]+)$" line)
    (if fullmatch
	;; meta table
	(let ((name (aref groups 0))
	      (timestamp (parse-integer (aref groups 1))))
	  (parse-meta parser name timestamp))
	;; table
	(multiple-value-bind (fullmatch groups)
	    (cl-ppcre:scan-to-strings "^XDUMP (.*) ([0-9]+)$" line)
	  (declare (ignorable fullmatch))
	  (let ((name (aref groups 0))
		(timestamp (parse-integer (aref groups 1))))
	    (parse-table parser name timestamp)))))
  nil)

(defun make-parser ()
  (let ((parser (make-instance 'xdump-parser)))
    (setf (line-parser parser) #'header-parser)
    parser))

(defmethod parse-line ((parser xdump-parser) line)
  (with-slots (line-parser) parser
    (funcall line-parser parser line)))

(defmethod parse-stream ((parser xdump-parser) stream)
  (loop for line = (read-line stream nil)
     while line do (parse-line parser line)))

(defmethod parse-file ((parser xdump-parser) filename)
  (with-open-file (s filename)
    (parse-stream parser s)))

(defun t1 ()
  (let ((parser (make-parser)))
    (setf *current-parser* parser)
    (parse-file parser "testdata/xdump-meta-meta.txt")))
  
(defun t2 ()
  (let ((parser (make-parser)))
    (setf *current-parser* parser)
    (parse-file parser "testdata/xdump-meta-meta.txt")
    (parse-file parser "testdata/xdump-meta-table.txt")
    (parse-file parser "testdata/xdump-table.txt")
    (parse-file parser "testdata/xdump-meta-34.txt")
    (parse-file parser "testdata/xdump-34.txt")))