client: Unbreak standalone build
[empserver] / m4 / ax_pthread.m4
1 # ===========================================================================
2 #        https://www.gnu.org/software/autoconf-archive/ax_pthread.html
3 # ===========================================================================
4 #
5 # SYNOPSIS
6 #
7 #   AX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
8 #
9 # DESCRIPTION
10 #
11 #   This macro figures out how to build C programs using POSIX threads. It
12 #   sets the PTHREAD_LIBS output variable to the threads library and linker
13 #   flags, and the PTHREAD_CFLAGS output variable to any special C compiler
14 #   flags that are needed. (The user can also force certain compiler
15 #   flags/libs to be tested by setting these environment variables.)
16 #
17 #   Also sets PTHREAD_CC to any special C compiler that is needed for
18 #   multi-threaded programs (defaults to the value of CC otherwise). (This
19 #   is necessary on AIX to use the special cc_r compiler alias.)
20 #
21 #   NOTE: You are assumed to not only compile your program with these flags,
22 #   but also to link with them as well. For example, you might link with
23 #   $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS $LIBS
24 #
25 #   If you are only building threaded programs, you may wish to use these
26 #   variables in your default LIBS, CFLAGS, and CC:
27 #
28 #     LIBS="$PTHREAD_LIBS $LIBS"
29 #     CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
30 #     CC="$PTHREAD_CC"
31 #
32 #   In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute constant
33 #   has a nonstandard name, this macro defines PTHREAD_CREATE_JOINABLE to
34 #   that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
35 #
36 #   Also HAVE_PTHREAD_PRIO_INHERIT is defined if pthread is found and the
37 #   PTHREAD_PRIO_INHERIT symbol is defined when compiling with
38 #   PTHREAD_CFLAGS.
39 #
40 #   ACTION-IF-FOUND is a list of shell commands to run if a threads library
41 #   is found, and ACTION-IF-NOT-FOUND is a list of commands to run it if it
42 #   is not found. If ACTION-IF-FOUND is not specified, the default action
43 #   will define HAVE_PTHREAD.
44 #
45 #   Please let the authors know if this macro fails on any platform, or if
46 #   you have any other suggestions or comments. This macro was based on work
47 #   by SGJ on autoconf scripts for FFTW (http://www.fftw.org/) (with help
48 #   from M. Frigo), as well as ac_pthread and hb_pthread macros posted by
49 #   Alejandro Forero Cuervo to the autoconf macro repository. We are also
50 #   grateful for the helpful feedback of numerous users.
51 #
52 #   Updated for Autoconf 2.68 by Daniel Richard G.
53 #
54 # LICENSE
55 #
56 #   Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
57 #   Copyright (c) 2011 Daniel Richard G. <skunk@iSKUNK.ORG>
58 #   Copyright (c) 2019 Marc Stevens <marc.stevens@cwi.nl>
59 #
60 #   This program is free software: you can redistribute it and/or modify it
61 #   under the terms of the GNU General Public License as published by the
62 #   Free Software Foundation, either version 3 of the License, or (at your
63 #   option) any later version.
64 #
65 #   This program is distributed in the hope that it will be useful, but
66 #   WITHOUT ANY WARRANTY; without even the implied warranty of
67 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
68 #   Public License for more details.
69 #
70 #   You should have received a copy of the GNU General Public License along
71 #   with this program. If not, see <https://www.gnu.org/licenses/>.
72 #
73 #   As a special exception, the respective Autoconf Macro's copyright owner
74 #   gives unlimited permission to copy, distribute and modify the configure
75 #   scripts that are the output of Autoconf when processing the Macro. You
76 #   need not follow the terms of the GNU General Public License when using
77 #   or distributing such scripts, even though portions of the text of the
78 #   Macro appear in them. The GNU General Public License (GPL) does govern
79 #   all other use of the material that constitutes the Autoconf Macro.
80 #
81 #   This special exception to the GPL applies to versions of the Autoconf
82 #   Macro released by the Autoconf Archive. When you make and distribute a
83 #   modified version of the Autoconf Macro, you may extend this special
84 #   exception to the GPL to apply to your modified version as well.
85
86 #serial 27
87
88 AU_ALIAS([ACX_PTHREAD], [AX_PTHREAD])
89 AC_DEFUN([AX_PTHREAD], [
90 AC_REQUIRE([AC_CANONICAL_HOST])
91 AC_REQUIRE([AC_PROG_CC])
92 AC_REQUIRE([AC_PROG_SED])
93 AC_LANG_PUSH([C])
94 ax_pthread_ok=no
95
96 # We used to check for pthread.h first, but this fails if pthread.h
97 # requires special compiler flags (e.g. on Tru64 or Sequent).
98 # It gets checked for in the link test anyway.
99
100 # First of all, check if the user has set any of the PTHREAD_LIBS,
101 # etcetera environment variables, and if threads linking works using
102 # them:
103 if test "x$PTHREAD_CFLAGS$PTHREAD_LIBS" != "x"; then
104         ax_pthread_save_CC="$CC"
105         ax_pthread_save_CFLAGS="$CFLAGS"
106         ax_pthread_save_LIBS="$LIBS"
107         AS_IF([test "x$PTHREAD_CC" != "x"], [CC="$PTHREAD_CC"])
108         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
109         LIBS="$PTHREAD_LIBS $LIBS"
110         AC_MSG_CHECKING([for pthread_join using $CC $PTHREAD_CFLAGS $PTHREAD_LIBS])
111         AC_LINK_IFELSE([AC_LANG_CALL([], [pthread_join])], [ax_pthread_ok=yes])
112         AC_MSG_RESULT([$ax_pthread_ok])
113         if test "x$ax_pthread_ok" = "xno"; then
114                 PTHREAD_LIBS=""
115                 PTHREAD_CFLAGS=""
116         fi
117         CC="$ax_pthread_save_CC"
118         CFLAGS="$ax_pthread_save_CFLAGS"
119         LIBS="$ax_pthread_save_LIBS"
120 fi
121
122 # We must check for the threads library under a number of different
123 # names; the ordering is very important because some systems
124 # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
125 # libraries is broken (non-POSIX).
126
127 # Create a list of thread flags to try. Items with a "," contain both
128 # C compiler flags (before ",") and linker flags (after ","). Other items
129 # starting with a "-" are C compiler flags, and remaining items are
130 # library names, except for "none" which indicates that we try without
131 # any flags at all, and "pthread-config" which is a program returning
132 # the flags for the Pth emulation library.
133
134 ax_pthread_flags="pthreads none -Kthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
135
136 # The ordering *is* (sometimes) important.  Some notes on the
137 # individual items follow:
138
139 # pthreads: AIX (must check this before -lpthread)
140 # none: in case threads are in libc; should be tried before -Kthread and
141 #       other compiler flags to prevent continual compiler warnings
142 # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
143 # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads), Tru64
144 #           (Note: HP C rejects this with "bad form for `-t' option")
145 # -pthreads: Solaris/gcc (Note: HP C also rejects)
146 # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
147 #      doesn't hurt to check since this sometimes defines pthreads and
148 #      -D_REENTRANT too), HP C (must be checked before -lpthread, which
149 #      is present but should not be used directly; and before -mthreads,
150 #      because the compiler interprets this as "-mt" + "-hreads")
151 # -mthreads: Mingw32/gcc, Lynx/gcc
152 # pthread: Linux, etcetera
153 # --thread-safe: KAI C++
154 # pthread-config: use pthread-config program (for GNU Pth library)
155
156 case $host_os in
157
158         freebsd*)
159
160         # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
161         # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
162
163         ax_pthread_flags="-kthread lthread $ax_pthread_flags"
164         ;;
165
166         hpux*)
167
168         # From the cc(1) man page: "[-mt] Sets various -D flags to enable
169         # multi-threading and also sets -lpthread."
170
171         ax_pthread_flags="-mt -pthread pthread $ax_pthread_flags"
172         ;;
173
174         openedition*)
175
176         # IBM z/OS requires a feature-test macro to be defined in order to
177         # enable POSIX threads at all, so give the user a hint if this is
178         # not set. (We don't define these ourselves, as they can affect
179         # other portions of the system API in unpredictable ways.)
180
181         AC_EGREP_CPP([AX_PTHREAD_ZOS_MISSING],
182             [
183 #            if !defined(_OPEN_THREADS) && !defined(_UNIX03_THREADS)
184              AX_PTHREAD_ZOS_MISSING
185 #            endif
186             ],
187             [AC_MSG_WARN([IBM z/OS requires -D_OPEN_THREADS or -D_UNIX03_THREADS to enable pthreads support.])])
188         ;;
189
190         solaris*)
191
192         # On Solaris (at least, for some versions), libc contains stubbed
193         # (non-functional) versions of the pthreads routines, so link-based
194         # tests will erroneously succeed. (N.B.: The stubs are missing
195         # pthread_cleanup_push, or rather a function called by this macro,
196         # so we could check for that, but who knows whether they'll stub
197         # that too in a future libc.)  So we'll check first for the
198         # standard Solaris way of linking pthreads (-mt -lpthread).
199
200         ax_pthread_flags="-mt,-lpthread pthread $ax_pthread_flags"
201         ;;
202 esac
203
204 # Are we compiling with Clang?
205
206 AC_CACHE_CHECK([whether $CC is Clang],
207     [ax_cv_PTHREAD_CLANG],
208     [ax_cv_PTHREAD_CLANG=no
209      # Note that Autoconf sets GCC=yes for Clang as well as GCC
210      if test "x$GCC" = "xyes"; then
211         AC_EGREP_CPP([AX_PTHREAD_CC_IS_CLANG],
212             [/* Note: Clang 2.7 lacks __clang_[a-z]+__ */
213 #            if defined(__clang__) && defined(__llvm__)
214              AX_PTHREAD_CC_IS_CLANG
215 #            endif
216             ],
217             [ax_cv_PTHREAD_CLANG=yes])
218      fi
219     ])
220 ax_pthread_clang="$ax_cv_PTHREAD_CLANG"
221
222
223 # GCC generally uses -pthread, or -pthreads on some platforms (e.g. SPARC)
224
225 # Note that for GCC and Clang -pthread generally implies -lpthread,
226 # except when -nostdlib is passed.
227 # This is problematic using libtool to build C++ shared libraries with pthread:
228 # [1] https://gcc.gnu.org/bugzilla/show_bug.cgi?id=25460
229 # [2] https://bugzilla.redhat.com/show_bug.cgi?id=661333
230 # [3] https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=468555
231 # To solve this, first try -pthread together with -lpthread for GCC
232
233 AS_IF([test "x$GCC" = "xyes"],
234       [ax_pthread_flags="-pthread,-lpthread -pthread -pthreads $ax_pthread_flags"])
235
236 # Clang takes -pthread (never supported any other flag), but we'll try with -lpthread first
237
238 AS_IF([test "x$ax_pthread_clang" = "xyes"],
239       [ax_pthread_flags="-pthread,-lpthread -pthread"])
240
241
242 # The presence of a feature test macro requesting re-entrant function
243 # definitions is, on some systems, a strong hint that pthreads support is
244 # correctly enabled
245
246 case $host_os in
247         darwin* | hpux* | linux* | osf* | solaris*)
248         ax_pthread_check_macro="_REENTRANT"
249         ;;
250
251         aix*)
252         ax_pthread_check_macro="_THREAD_SAFE"
253         ;;
254
255         *)
256         ax_pthread_check_macro="--"
257         ;;
258 esac
259 AS_IF([test "x$ax_pthread_check_macro" = "x--"],
260       [ax_pthread_check_cond=0],
261       [ax_pthread_check_cond="!defined($ax_pthread_check_macro)"])
262
263
264 if test "x$ax_pthread_ok" = "xno"; then
265 for ax_pthread_try_flag in $ax_pthread_flags; do
266
267         case $ax_pthread_try_flag in
268                 none)
269                 AC_MSG_CHECKING([whether pthreads work without any flags])
270                 ;;
271
272                 *,*)
273                 PTHREAD_CFLAGS=`echo $ax_pthread_try_flag | sed "s/^\(.*\),\(.*\)$/\1/"`
274                 PTHREAD_LIBS=`echo $ax_pthread_try_flag | sed "s/^\(.*\),\(.*\)$/\2/"`
275                 AC_MSG_CHECKING([whether pthreads work with "$PTHREAD_CFLAGS" and "$PTHREAD_LIBS"])
276                 ;;
277
278                 -*)
279                 AC_MSG_CHECKING([whether pthreads work with $ax_pthread_try_flag])
280                 PTHREAD_CFLAGS="$ax_pthread_try_flag"
281                 ;;
282
283                 pthread-config)
284                 AC_CHECK_PROG([ax_pthread_config], [pthread-config], [yes], [no])
285                 AS_IF([test "x$ax_pthread_config" = "xno"], [continue])
286                 PTHREAD_CFLAGS="`pthread-config --cflags`"
287                 PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
288                 ;;
289
290                 *)
291                 AC_MSG_CHECKING([for the pthreads library -l$ax_pthread_try_flag])
292                 PTHREAD_LIBS="-l$ax_pthread_try_flag"
293                 ;;
294         esac
295
296         ax_pthread_save_CFLAGS="$CFLAGS"
297         ax_pthread_save_LIBS="$LIBS"
298         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
299         LIBS="$PTHREAD_LIBS $LIBS"
300
301         # Check for various functions.  We must include pthread.h,
302         # since some functions may be macros.  (On the Sequent, we
303         # need a special flag -Kthread to make this header compile.)
304         # We check for pthread_join because it is in -lpthread on IRIX
305         # while pthread_create is in libc.  We check for pthread_attr_init
306         # due to DEC craziness with -lpthreads.  We check for
307         # pthread_cleanup_push because it is one of the few pthread
308         # functions on Solaris that doesn't have a non-functional libc stub.
309         # We try pthread_create on general principles.
310
311         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>
312 #                       if $ax_pthread_check_cond
313 #                        error "$ax_pthread_check_macro must be defined"
314 #                       endif
315                         static void *some_global = NULL;
316                         static void routine(void *a)
317                           {
318                              /* To avoid any unused-parameter or
319                                 unused-but-set-parameter warning.  */
320                              some_global = a;
321                           }
322                         static void *start_routine(void *a) { return a; }],
323                        [pthread_t th; pthread_attr_t attr;
324                         pthread_create(&th, 0, start_routine, 0);
325                         pthread_join(th, 0);
326                         pthread_attr_init(&attr);
327                         pthread_cleanup_push(routine, 0);
328                         pthread_cleanup_pop(0) /* ; */])],
329             [ax_pthread_ok=yes],
330             [])
331
332         CFLAGS="$ax_pthread_save_CFLAGS"
333         LIBS="$ax_pthread_save_LIBS"
334
335         AC_MSG_RESULT([$ax_pthread_ok])
336         AS_IF([test "x$ax_pthread_ok" = "xyes"], [break])
337
338         PTHREAD_LIBS=""
339         PTHREAD_CFLAGS=""
340 done
341 fi
342
343
344 # Clang needs special handling, because older versions handle the -pthread
345 # option in a rather... idiosyncratic way
346
347 if test "x$ax_pthread_clang" = "xyes"; then
348
349         # Clang takes -pthread; it has never supported any other flag
350
351         # (Note 1: This will need to be revisited if a system that Clang
352         # supports has POSIX threads in a separate library.  This tends not
353         # to be the way of modern systems, but it's conceivable.)
354
355         # (Note 2: On some systems, notably Darwin, -pthread is not needed
356         # to get POSIX threads support; the API is always present and
357         # active.  We could reasonably leave PTHREAD_CFLAGS empty.  But
358         # -pthread does define _REENTRANT, and while the Darwin headers
359         # ignore this macro, third-party headers might not.)
360
361         # However, older versions of Clang make a point of warning the user
362         # that, in an invocation where only linking and no compilation is
363         # taking place, the -pthread option has no effect ("argument unused
364         # during compilation").  They expect -pthread to be passed in only
365         # when source code is being compiled.
366         #
367         # Problem is, this is at odds with the way Automake and most other
368         # C build frameworks function, which is that the same flags used in
369         # compilation (CFLAGS) are also used in linking.  Many systems
370         # supported by AX_PTHREAD require exactly this for POSIX threads
371         # support, and in fact it is often not straightforward to specify a
372         # flag that is used only in the compilation phase and not in
373         # linking.  Such a scenario is extremely rare in practice.
374         #
375         # Even though use of the -pthread flag in linking would only print
376         # a warning, this can be a nuisance for well-run software projects
377         # that build with -Werror.  So if the active version of Clang has
378         # this misfeature, we search for an option to squash it.
379
380         AC_CACHE_CHECK([whether Clang needs flag to prevent "argument unused" warning when linking with -pthread],
381             [ax_cv_PTHREAD_CLANG_NO_WARN_FLAG],
382             [ax_cv_PTHREAD_CLANG_NO_WARN_FLAG=unknown
383              # Create an alternate version of $ac_link that compiles and
384              # links in two steps (.c -> .o, .o -> exe) instead of one
385              # (.c -> exe), because the warning occurs only in the second
386              # step
387              ax_pthread_save_ac_link="$ac_link"
388              ax_pthread_sed='s/conftest\.\$ac_ext/conftest.$ac_objext/g'
389              ax_pthread_link_step=`$as_echo "$ac_link" | sed "$ax_pthread_sed"`
390              ax_pthread_2step_ac_link="($ac_compile) && (echo ==== >&5) && ($ax_pthread_link_step)"
391              ax_pthread_save_CFLAGS="$CFLAGS"
392              for ax_pthread_try in '' -Qunused-arguments -Wno-unused-command-line-argument unknown; do
393                 AS_IF([test "x$ax_pthread_try" = "xunknown"], [break])
394                 CFLAGS="-Werror -Wunknown-warning-option $ax_pthread_try -pthread $ax_pthread_save_CFLAGS"
395                 ac_link="$ax_pthread_save_ac_link"
396                 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(void){return 0;}]])],
397                     [ac_link="$ax_pthread_2step_ac_link"
398                      AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(void){return 0;}]])],
399                          [break])
400                     ])
401              done
402              ac_link="$ax_pthread_save_ac_link"
403              CFLAGS="$ax_pthread_save_CFLAGS"
404              AS_IF([test "x$ax_pthread_try" = "x"], [ax_pthread_try=no])
405              ax_cv_PTHREAD_CLANG_NO_WARN_FLAG="$ax_pthread_try"
406             ])
407
408         case "$ax_cv_PTHREAD_CLANG_NO_WARN_FLAG" in
409                 no | unknown) ;;
410                 *) PTHREAD_CFLAGS="$ax_cv_PTHREAD_CLANG_NO_WARN_FLAG $PTHREAD_CFLAGS" ;;
411         esac
412
413 fi # $ax_pthread_clang = yes
414
415
416
417 # Various other checks:
418 if test "x$ax_pthread_ok" = "xyes"; then
419         ax_pthread_save_CFLAGS="$CFLAGS"
420         ax_pthread_save_LIBS="$LIBS"
421         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
422         LIBS="$PTHREAD_LIBS $LIBS"
423
424         # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
425         AC_CACHE_CHECK([for joinable pthread attribute],
426             [ax_cv_PTHREAD_JOINABLE_ATTR],
427             [ax_cv_PTHREAD_JOINABLE_ATTR=unknown
428              for ax_pthread_attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
429                  AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>],
430                                                  [int attr = $ax_pthread_attr; return attr /* ; */])],
431                                 [ax_cv_PTHREAD_JOINABLE_ATTR=$ax_pthread_attr; break],
432                                 [])
433              done
434             ])
435         AS_IF([test "x$ax_cv_PTHREAD_JOINABLE_ATTR" != "xunknown" && \
436                test "x$ax_cv_PTHREAD_JOINABLE_ATTR" != "xPTHREAD_CREATE_JOINABLE" && \
437                test "x$ax_pthread_joinable_attr_defined" != "xyes"],
438               [AC_DEFINE_UNQUOTED([PTHREAD_CREATE_JOINABLE],
439                                   [$ax_cv_PTHREAD_JOINABLE_ATTR],
440                                   [Define to necessary symbol if this constant
441                                    uses a non-standard name on your system.])
442                ax_pthread_joinable_attr_defined=yes
443               ])
444
445         AC_CACHE_CHECK([whether more special flags are required for pthreads],
446             [ax_cv_PTHREAD_SPECIAL_FLAGS],
447             [ax_cv_PTHREAD_SPECIAL_FLAGS=no
448              case $host_os in
449              solaris*)
450              ax_cv_PTHREAD_SPECIAL_FLAGS="-D_POSIX_PTHREAD_SEMANTICS"
451              ;;
452              esac
453             ])
454         AS_IF([test "x$ax_cv_PTHREAD_SPECIAL_FLAGS" != "xno" && \
455                test "x$ax_pthread_special_flags_added" != "xyes"],
456               [PTHREAD_CFLAGS="$ax_cv_PTHREAD_SPECIAL_FLAGS $PTHREAD_CFLAGS"
457                ax_pthread_special_flags_added=yes])
458
459         AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
460             [ax_cv_PTHREAD_PRIO_INHERIT],
461             [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]],
462                                              [[int i = PTHREAD_PRIO_INHERIT;
463                                                return i;]])],
464                             [ax_cv_PTHREAD_PRIO_INHERIT=yes],
465                             [ax_cv_PTHREAD_PRIO_INHERIT=no])
466             ])
467         AS_IF([test "x$ax_cv_PTHREAD_PRIO_INHERIT" = "xyes" && \
468                test "x$ax_pthread_prio_inherit_defined" != "xyes"],
469               [AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], [1], [Have PTHREAD_PRIO_INHERIT.])
470                ax_pthread_prio_inherit_defined=yes
471               ])
472
473         CFLAGS="$ax_pthread_save_CFLAGS"
474         LIBS="$ax_pthread_save_LIBS"
475
476         # More AIX lossage: compile with *_r variant
477         if test "x$GCC" != "xyes"; then
478             case $host_os in
479                 aix*)
480                 AS_CASE(["x/$CC"],
481                     [x*/c89|x*/c89_128|x*/c99|x*/c99_128|x*/cc|x*/cc128|x*/xlc|x*/xlc_v6|x*/xlc128|x*/xlc128_v6],
482                     [#handle absolute path differently from PATH based program lookup
483                      AS_CASE(["x$CC"],
484                          [x/*],
485                          [AS_IF([AS_EXECUTABLE_P([${CC}_r])],[PTHREAD_CC="${CC}_r"])],
486                          [AC_CHECK_PROGS([PTHREAD_CC],[${CC}_r],[$CC])])])
487                 ;;
488             esac
489         fi
490 fi
491
492 test -n "$PTHREAD_CC" || PTHREAD_CC="$CC"
493
494 AC_SUBST([PTHREAD_LIBS])
495 AC_SUBST([PTHREAD_CFLAGS])
496 AC_SUBST([PTHREAD_CC])
497
498 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
499 if test "x$ax_pthread_ok" = "xyes"; then
500         ifelse([$1],,[AC_DEFINE([HAVE_PTHREAD],[1],[Define if you have POSIX threads libraries and header files.])],[$1])
501         :
502 else
503         ax_pthread_ok=no
504         $2
505 fi
506 AC_LANG_POP
507 ])dnl AX_PTHREAD