git.pond.sub.org Git - eow/blob - empire.lisp

   1 (in-package :empire)
   2
   3 (defparameter *version* "0.0.1")
   4
   5 ;;
   6 ;; Connection
   7 ;;
   8
   9 (defvar *default-empire-server* "localhost")
  10 (defvar *default-empire-server-port* 6665)
  11
  12 (defclass connection ()
  13   ((user
  14     :initarg :user
  15     :accessor user)
  16    (password
  17     :initarg :password
  18     :accessor password
  19     :initform nil)
  20    (server-name
  21     :initarg :server-name
  22     :accessor server-name
  23     :initform "Unknown server")
  24    (server-port
  25     :initarg :server-port
  26     :accessor server-port
  27     :initform *default-empire-server-port*)
  28    (socket
  29     :initarg :socket
  30     :accessor socket
  31     :documentation "Slot to store socket (for internal use only).")
  32    (stream
  33     :initarg :stream
  34     :accessor network-stream
  35     :documentation "Stream used to talk to the empire server.")
  36    (connection-handler
  37     :accessor connection-handler
  38     :initform nil
  39     :documentation "Handler function for incoming messages")
  40    (mode
  41     :accessor connection-mode
  42     :initform nil
  43     :documentation "TODO(gefla)")
  44    (session
  45     :accessor session
  46     :initarg :session
  47     :documentation "web session to which this connection belongs")))
  48
  49 (defun make-connection (&key (user nil)
  50                         (password nil)
  51                         (server-name *default-empire-server*)
  52                         (server-port *default-empire-server-port*)
  53                         (socket nil)
  54                         (network-stream nil)
  55                         session)
  56   (make-instance 'connection
  57                  :user user
  58                  :password password
  59                  :server-name server-name
  60                  :server-port server-port
  61                  :socket socket
  62                  :stream network-stream
  63                  :session session))
  64
  65 ;;; interface
  66 (defun connect  (&key (user nil)
  67                  (password nil)
  68                  (server-name *default-empire-server*)
  69                  (server-port *default-empire-server-port*)
  70                  session)
  71   "Connect to server and return a connection object."
  72   (let* ((socket (usocket:socket-connect server-name server-port))
  73          (stream (usocket:socket-stream socket))
  74          (connection (make-connection :user user
  75                                       :password password
  76                                       :socket socket
  77                                       :network-stream stream
  78                                       :server-name server-name
  79                                       :server-port server-port
  80                                       :session session))
  81          (handler (spawn-with-name (format nil "empire-handler-~a" user)
  82                                    #'handle-connection connection)))
  83     (setf (connection-handler connection) handler)
  84     (empire-log:info "empire:connect: ~a" connection)
  85     connection))
  86
  87 (defgeneric quit (connection))
  88 (defgeneric handle-connection (connection))
  89 (defgeneric read-message (connection))
  90 (defgeneric send-message (connection message))
  91 (defgeneric reconnect (conncetion))
  92
  93 (defmethod reconnect ((c connection))
  94   (with-slots (server-name server-port user password socket stream connection-handler) c
  95       (let* ((sock (usocket:socket-connect server-name server-port))
  96              (s (usocket:socket-stream sock))
  97              (handler (spawn-with-name (format nil "empire-handler-~a" user)
  98                                        #'handle-connection c)))
  99         (setf socket sock
 100               stream s
 101               connection-handler handler)))
 102   (empire-log:info "empire:reconnect: ~a" c))
 103
 104 (defparameter +C_CMDOK+ "0")
 105 (defparameter +C_DATA+ "1")
 106 (defparameter +C_INIT+ "2")
 107 (defparameter +C_EXIT+ "3")
 108 (defparameter +C_FLUSH+ "4")
 109 (defparameter +C_NOECHO+ "5")
 110 (defparameter +C_PROMPT+ "6")
 111 (defparameter +C_ABORT+ "7")
 112 (defparameter +C_REDIR+ "8")
 113 (defparameter +C_PIPE+ "9")
 114 (defparameter +C_CMDERR+ "a")
 115 (defparameter +C_BADCMD+ "b")
 116 (defparameter +C_EXECUTE+ "c")
 117 (defparameter +C_FLASH+ "d")
 118 (defparameter +C_INFORM+ "e")
 119
 120 (defclass base-mode ()
 121   ((connection :initarg :connection :accessor connection)))
 122 (defclass init-mode (base-mode)
 123   ((play-sent-p :initform nil
 124                 :documentation "Have we already sent the play command?")))
 125 (defclass play-mode (base-mode) nil)
 126
 127 (defun make-mode (connection mode)
 128   (make-instance mode :connection connection))
 129
 130 (defgeneric set-new-mode (base-mode new-mode))
 131 (defmethod set-new-mode ((m base-mode) new-mode)
 132   (let* ((c (connection m))
 133          (mode (make-mode c new-mode)))
 134     (setf (connection-mode c) mode)))
 135
 136 (defgeneric handle-data (base-mode message))
 137 (defgeneric handle-init (base-mode message))
 138 (defgeneric handle-exit (base-mode message))
 139 (defgeneric handle-prompt (base-mode message))
 140 (defgeneric handle-flush (base-mode message))
 141 (defgeneric handle-simple-message (base-mode message))
 142
 143 (defmethod handle-init ((m init-mode) message)
 144   (declare (ignorable message))
 145   (with-slots (play-sent-p) m
 146     (if (not play-sent-p)
 147         (progn
 148           (play (connection m))
 149           (setf play-sent-p t))
 150         (set-new-mode m 'play-mode))))
 151
 152 (defmethod handle-exit ((m init-mode) message)
 153   (declare (ignorable message))
 154   (quit (connection m)))
 155
 156 (defmethod handle-exit ((m play-mode) message)
 157   (declare (ignorable message))
 158   (quit (connection m)))
 159
 160 (defmethod handle-data ((m play-mode) message)
 161   (let* ((c (connection m)))
 162     (empire-web:data (session c) message)))
 163
 164 (defmethod handle-simple-message ((m play-mode) message)
 165   (let* ((c (connection m)))
 166     (empire-web:data (session c) message)))
 167
 168 (defmethod handle-flush ((m play-mode) message)
 169   (let* ((c (connection m)))
 170     (empire-web:prompt (session c) message)))
 171
 172 (defmethod handle-prompt ((m play-mode) message)
 173   (let* ((c (connection m)))
 174     (with-input-from-string (s message)
 175       (let* ((minutes (read s)) ;;FIXME DANGEROUS
 176              (btus (read s)))
 177         (empire-web:prompt (session c)
 178                            (format nil "[~a,~a]: " minutes btus))))))
 179
 180 (defparameter *line-type-dispatch*
 181   (list `(,+C_DATA+ . handle-data)
 182         `(,+C_INIT+ . handle-init)
 183         `(,+C_EXIT+ . handle-exit)
 184         `(,+C_FLUSH+ . handle-flush)
 185         `(,+C_BADCMD+ . handle-simple-message)
 186         `(,+C_FLASH+ . handle-simple-message)
 187         `(,+C_PROMPT+ . handle-prompt)))
 188
 189 (defun parse-server-line (line)
 190   (let* ((first-space-index
 191           (loop for i from 0 below (length line)
 192              if (eq (char line i) #\Space)
 193              do (return i)))
 194          (message-type (subseq line 0 first-space-index))
 195          (message (if first-space-index
 196                       (subseq line (+ first-space-index 1))
 197                       "")))
 198     (values message message-type)))
 199
 200 (defmethod handle-connection ((c connection))
 201   (setf (connection-mode c) (make-mode c 'init-mode))
 202   (loop while (read-message c)))
 203
 204 (defun lookup-handler (message-type)
 205   (cdr (assoc message-type *line-type-dispatch* :test 'string=)))
 206
 207 (define-condition no-handler (error)
 208   ((mode :initarg :mode)
 209    (type :initarg :type))
 210   (:report (lambda (condition stream)
 211              (with-slots (mode type) condition
 212                (format stream "No handler for ~a in mode ~a."
 213                        type mode)))))
 214 (defmethod read-message ((c connection))
 215   (handler-case
 216       (let* ((s (network-stream c))
 217              (line (read-line s)))
 218         (empire-log:info "< ~a~%" line)
 219         (multiple-value-bind (message type) (parse-server-line line)
 220           (let ((handler (lookup-handler type))
 221                 (mode (connection-mode c)))
 222             (if handler
 223                 (funcall handler mode message)
 224                 (error 'no-handler :mode mode :type type))))
 225         line)
 226     (sb-int:closed-stream-error () nil)
 227     (end-of-file () nil)))
 228
 229 (defun raw-send-message (s message)
 230     (write-sequence message s)
 231     (terpri s)
 232     (force-output s))
 233
 234 (defmethod send-message ((c connection) message)
 235   (let ((s (network-stream c)))
 236     (empire-log:info "> ~a~%" message)
 237     (let ((sent-p nil)
 238           (tries 3))
 239       (loop
 240          while (and (not sent-p)
 241                     (> tries 0))
 242          do (handler-case
 243                 (progn
 244                   (raw-send-message s message)
 245                   (setf sent-p t))
 246               (sb-int:closed-stream-error ()
 247                 (progn
 248                   (decf tries)
 249                   (empire-log:info "Connection close - retrying (~a tries left)" tries)
 250                   (reconnect c))))))
 251     message))
 252
 253 (defgeneric play (connection))
 254 (defmethod play ((c connection))
 255   (with-slots (user password) c
 256     (send-message c (format nil "play FIXME ~a ~a" user password))))
 257
 258 (defmethod quit ((c connection))
 259   (usocket:socket-close (socket c)))
 260
 261
 262 ;;; Tests
 263 (defvar *l1* "2 Empire server ready")
 264 ;; (parse-server-line *l1*)