replace dojo byId by own version
[eow] / empire.lisp
1 (in-package :empire)
2
3 (defparameter *version* "0.0.1")
4
5 ;;
6 ;; Connection
7 ;;
8
9 (defvar *default-empire-server* "localhost")
10 (defvar *default-empire-server-port* 6665)
11
12 (defclass connection ()
13   ((user
14     :initarg :user
15     :accessor user)
16    (password
17     :initarg :password
18     :accessor password
19     :initform nil)
20    (server-name
21     :initarg :server-name
22     :accessor server-name
23     :initform "Unknown server")
24    (server-port
25     :initarg :server-port
26     :accessor server-port
27     :initform *default-empire-server-port*)
28    (socket
29     :initarg :socket
30     :accessor socket
31     :documentation "Slot to store socket (for internal use only).")
32    (stream
33     :initarg :stream
34     :accessor network-stream
35     :documentation "Stream used to talk to the empire server.")
36    (logging-stream
37     :initarg :logging-stream
38     :accessor logging-stream
39     :initform t
40     :documentation "Messages coming back from the server is sent to
41 this stream.")
42    (connection-handler
43     :accessor connection-handler
44     :initform nil
45     :documentation "Handler function for incoming messages")
46    (mode
47     :accessor connection-mode
48     :initform nil
49     :documentation "TODO(gefla)")
50    (session
51     :accessor session
52     :initarg :session
53     :documentation "web session to which this connection belongs")))
54
55 (defun make-connection (&key (user nil)
56                         (password nil)
57                         (server-name *default-empire-server*)
58                         (server-port *default-empire-server-port*)
59                         (socket nil)
60                         (network-stream nil)
61                         (logging-stream nil)
62                         session)
63   (make-instance 'connection
64                  :user user
65                  :password password
66                  :server-name server-name
67                  :server-port server-port
68                  :socket socket
69                  :stream network-stream
70                  :logging-stream logging-stream
71                  :session session))
72
73 ;;; interface
74 (defun connect  (&key (user nil)
75                  (password nil)
76                  (server-name *default-empire-server*)
77                  (server-port *default-empire-server-port*)
78                  (logging-stream *standard-output*)
79                  session)
80   "Connect to server and return a connection object."
81   (let* ((socket (usocket:socket-connect server-name server-port))
82          (stream (usocket:socket-stream socket))
83          (connection (make-connection :user user
84                                       :password password
85                                       :socket socket
86                                       :network-stream stream
87                                       :logging-stream logging-stream
88                                       :server-name server-name
89                                       :server-port server-port
90                                       :session session))
91          (handler (spawn-with-name (format nil "empire-handler-~a" user)
92                                    #'handle-connection connection)))
93     (setf (connection-handler connection) handler)
94     connection))
95
96
97 (defgeneric quit (connection))
98 (defgeneric handle-connection (connection))
99 (defgeneric read-message (connection))
100 (defgeneric send-message (connection message))
101
102 (defparameter +C_CMDOK+ "0")
103 (defparameter +C_DATA+ "1")
104 (defparameter +C_INIT+ "2")
105 (defparameter +C_EXIT+ "3")
106 (defparameter +C_FLUSH+ "4")
107 (defparameter +C_NOECHO+ "5")
108 (defparameter +C_PROMPT+ "6")
109 (defparameter +C_ABORT+ "7")
110 (defparameter +C_REDIR+ "8")
111 (defparameter +C_PIPE+ "9")
112 (defparameter +C_CMDERR+ "a")
113 (defparameter +C_BADCMD+ "b")
114 (defparameter +C_EXECUTE+ "c")
115 (defparameter +C_FLASH+ "d")
116 (defparameter +C_INFORM+ "e")
117
118 (defclass base-mode ()
119   ((connection :initarg :connection :accessor connection)))
120 (defclass init-mode (base-mode)
121   ((play-sent-p :initform nil
122                 :documentation "Have we already sent the play command?")))
123 (defclass play-mode (base-mode) nil)
124
125 (defun make-mode (connection mode)
126   (make-instance mode :connection connection))
127
128 (defgeneric set-new-mode (base-mode new-mode))
129 (defmethod set-new-mode ((m base-mode) new-mode)
130   (let* ((c (connection m))
131          (mode (make-mode c new-mode)))
132     (setf (connection-mode c) mode)))
133
134 (defgeneric handle-data (base-mode message))
135 (defgeneric handle-init (base-mode message))
136 (defgeneric handle-exit (base-mode message))
137 (defgeneric handle-prompt (base-mode message))
138
139 (defmethod handle-init ((m init-mode) message)
140   (declare (ignorable message))
141   (with-slots (play-sent-p) m
142     (if (not play-sent-p)
143         (progn 
144           (play (connection m))
145           (setf play-sent-p t))
146         (set-new-mode m 'play-mode))))
147
148 (defmethod handle-exit ((m init-mode) message)
149   (declare (ignorable message))
150   (quit (connection m)))
151
152 (defmethod handle-exit ((m play-mode) message)
153   (declare (ignorable message))
154   (quit (connection m)))
155
156 (defmethod handle-data ((m play-mode) message)
157   (let* ((c (connection m))
158          (log (logging-stream c)))
159     (format log "handle-data ~a~%" message)
160     (empire-web:data (session c) message)))
161
162 (defmethod handle-prompt ((m play-mode) message)
163   (let* ((c (connection m))
164          (log (logging-stream c)))
165     (with-input-from-string (s message)
166       (let* ((minutes (read s)) ;;FIXME DANGEROUS
167              (btus (read s)))
168         (format log "[~a:~a]: ~%" minutes btus)
169         (empire-web:prompt (session c) minutes btus)))))
170
171 (defparameter *line-type-dispatch*
172   (list `(,+C_DATA+ . handle-data)
173         `(,+C_INIT+ . handle-init)
174         `(,+C_EXIT+ . handle-exit)
175         `(,+C_PROMPT+ . handle-prompt)))
176
177 (defun parse-server-line (line)
178   (let* ((first-space-index
179           (loop for i from 0 below (length line)
180              if (eq (char line i) #\Space)
181              do (return i)))
182          (message-type (subseq line 0 first-space-index))
183          (message (subseq line (+ first-space-index 1))))
184     (values message message-type)))
185
186 (defmethod handle-connection ((c connection))
187   (setf (connection-mode c) (make-mode c 'init-mode))
188   (loop while (read-message c)))
189
190 (defun lookup-handler (message-type)
191   (cdr (assoc message-type *line-type-dispatch* :test 'string=)))
192
193 (define-condition no-handler (error)
194   ((mode :initarg :mode)
195    (type :initarg :type))
196   (:report (lambda (condition stream)
197              (with-slots (mode type) condition
198                (format stream "No handler for ~a in mode ~a."
199                        type mode)))))
200 (defmethod read-message ((c connection))
201   (handler-case
202       (let* ((s (network-stream c))
203              (log (logging-stream c))
204              (line (read-line s)))
205         (format log "< ~a~%" line)
206         (multiple-value-bind (message type) (parse-server-line line)
207           (let ((handler (lookup-handler type))
208                 (mode (connection-mode c)))
209             (if handler
210                 (funcall handler mode message)
211                 (error 'no-handler :mode mode :type type))))
212         line)
213     (sb-int:closed-stream-error () nil)))
214   
215 (defmethod send-message ((c connection) message)
216   (let ((s (network-stream c))
217         (log (logging-stream c)))
218     (format log "< ~a~%" message)
219     (write-sequence message s)
220     (terpri s)
221     (force-output s)
222     message))
223
224 (defgeneric play (connection))
225 (defmethod play ((c connection))
226   (with-slots (user password) c
227     (send-message c (format nil "play FIXME ~a ~a" user password))))
228
229 (defmethod quit ((c connection))
230   (usocket:socket-close (socket c)))
231
232
233 ;;; Tests
234 (defvar *l1* "2 Empire server ready")
235 ;; (parse-server-line *l1*)